Deleting parts from a nested list

Question

I have a very long nested list. Here is a short example:

list = {{1.2, {1, 1, 1, 1}, {2, 2, 2}}, {0.9, {3, 3, 3, 3}, {4, 4, 4}}, {1.4, {4, 4, 4, 4}, {5, 5, 5}}}

Now I want to cancel all entries if the first entry of each part of the list (list[[i]]) is > 1. So that the new list would only consist of the second part of list (list[[2]])

newlist = {0.9, {3, 3, 3, 3}, {4, 4, 4}}

I have already tried my luck with Position and Delete, but with no success.

Thanks a lot for your help!

This is a very common type of question. (I may close it as a duplicate.) I agree with Pinguin Dirk's use of Pick, e.g. my own answers to (900) and (30155) — Mr.Wizard, Dec 20 '13 at 16:57
@belisarius That's too complicated; you need merely this: Cases[list, {x_, a__} /; x <= 1]. Also don't forget to use :> with named patterns! — Mr.Wizard, Dec 20 '13 at 17:21
I believe that the output you are looking for is a sublist of list, it should therefore be {{0.9, {3, 3, 3, 3}, {4, 4, 4}}} (note the extra {}) -- Unless you know that only one item will be selected. — A.G., Dec 20 '13 at 18:42

score 3 · Answer 1 · answered Dec 20 '13 at 16:28

3

A solution using Pick:

Pick[list, UnitStep[list[[All, 1]] - 1], 0]

(I subtract one from the first element and then grab all positions with a negative such element)

answered Dec 20 '13 at 16:28

Pinguin Dirk

6,519
1
26
36

Great idea. Thanks a lot – Anna Dec 20 '13 at 16:49

bill s · Accepted Answer · 2013-12-20T18:30:10.670

2

Rather than think of it as deleting certain unwanted parts of the list, you can equivalently think of it as selecting the parts you wish to keep. Accordingly, Select can be straightforwardly applied

Select[list, #[[1]] < 1 &]
{{0.9, {3, 3, 3, 3}, {4, 4, 4}}}

A. G. points out that this can be made more transparent by replacing the perhaps somewhat cryptic Part command [[1]] with

Select[list, First[#] < 1 &]

You can Flatten[%, 1] if you wish to get the levels exactly as described in the question.

edited Dec 20 '13 at 18:30

answered Dec 20 '13 at 17:26

bill s

68,936
4
101
191

Note that #[[1]] can also be written First[#] or First@# or even (# // First) !!! – A.G. Dec 20 '13 at 18:14

score 1 · Answer 3 · answered Feb 26 '24 at 23:58

1

list = {{1.2, {1, 1, 1, 1}, {2, 2, 2}},
        {0.9, {3, 3, 3, 3}, {4, 4, 4}},
        {1.4, {4, 4, 4, 4}, {5, 5, 5}}};

Using Replace:

Replace[list, {a_ /; a > 1, ___} :> Nothing, {1}]
({{0.9, {3, 3, 3, 3}, {4, 4, 4}}})

answered Feb 26 '24 at 23:58

E. Chan-López

23,117
3
21
44

score 1 · Answer 4 · answered Feb 27 '24 at 00:23

list = 
 {{1.2, {1, 1, 1, 1}, {2, 2, 2}}, 
  {0.9, {3, 3, 3, 3}, {4, 4, 4}}, 
  {1.4, {4, 4, 4, 4}, {5, 5, 5}}};

via Position

p = Position[list, {x_ /; x > 1, __}, 1]

{{1}, {3}}

Using Delete

Delete[p] @ list

{{0.9, {3, 3, 3, 3}, {4, 4, 4}}}

Using ReplaceAt (new in 13.1)

ReplaceAt[_ :> Nothing, p] @ list

{{0.9, {3, 3, 3, 3}, {4, 4, 4}}}

score 1 · Answer 5 · answered Feb 27 '24 at 06:16

1

Using Sow/Reap:

list = {{1.2, {1, 1, 1, 1}, {2, 2, 2}}, {0.9, {3, 3, 3, 3}, {4, 4, 
    4}}, {1.4, {4, 4, 4, 4}, {5, 5, 5}}}
Scan[
    If[First@# < 1, Sow@#, Nothing] &
    , list] //
   Reap // Last // First

{{0.9, {3, 3, 3, 3}, {4, 4, 4}}}

answered Feb 27 '24 at 06:16

Syed

52,495
4
30
85

Deleting parts from a nested list

5 Answers5