Detect a graphic primitive inside a Graphic

Question

Please excuse me if that question is too basic but I couldn't find anything in the documentation or on here.

If you consider the following Graphic I would like to know how to detect which primitive is being clicked,

Graphics[{Disk[#, 0.5]} & /@ {{0, 0}, {1, 0}}]

and for example change the color of the clicked Disk, change its radius or get the coordinates of its center or anything related to its geometry.

I am aware that EventHandler is my friend but as the questions states, I have no clue how to detect which primitive is being clicked (except by using Mouseposition and compare it to the centers).

I am also aware that my question is somehow poorly researched but I feel like I'm blocking on a basic notion.

Answer 1

EventHandler can be used to catch various mouse events (mouse up, mouse down, mouse clicked, mouse dragged). Use MousePosition to add some intelligence.

Example:

DynamicModule[{col1 = Green, col2 = Blue}, Graphics[
  {
   EventHandler[
    Dynamic[{col1, Disk[]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col1 = 
        col1 /. {Red -> Green, Green -> Red})}],
   EventHandler[
    Dynamic[{col2, Disk[{1, 1}]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col2 = 
        col2 /. {Blue -> Yellow, Yellow -> Blue})}]
   }
  ]
 ]

The circles can be clicked independently. An action is defined for each object separately.

Amazingly, this even works for 3D Graphics:

DynamicModule[{col1 = Green, col2 = Blue}, 
 Graphics3D[
  {
   EventHandler[
    Dynamic[{col1, Sphere[]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col1 = 
        col1 /. {Red -> Green, Green -> Red})}], 
   EventHandler[
    Dynamic[{col2, Sphere[{1, 1, 1}]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col2 = 
        col2 /. {Blue -> Yellow, Yellow -> Blue})}]
   }
  ]
 ]

Here's some code to test the scalability:

With[{n = 100},
 DynamicModule[{col = RGBColor @@@ RandomReal[{0, 1}, {n, 3}]},
  Graphics[
   Table[
    With[{j = i},
     EventHandler[
      {Dynamic[col[[j]]], Disk[RandomReal[{-10, 10}, {2}]]}, 
      ImageSize -> Tiny,
      {"MouseClicked" :> (col[[j]] = 
          RGBColor @@ RandomReal[{0, 1}, {3}])}
      ]
     ], {i, n}
    ]
   ]
  ]
 ]

This is reasonably responsive. However, try the version with n=1000:

On my PC the color changes only after about three seconds. So, if you need to interact with many objects this may not be the best solution.