Is it possible to use Mathematica to record sound and/or vision?

Question

I think the title says it all. I know about ImageCapture which seems to capture stills.

Can ImageCapture be made to capture a movie analogous to using say QuickTime player (and export to video format)?

Likewise, if a microphone is connected to your computer (e.g. something that can be used by QuickTime to record) can Mathematica record sound?

Edit

Because I was aware of ImageCapture prior to posting this question I did some searches looking for functions that may involve recording e.g.:

?*ecord*

But got no hits. It is frustrating to find that capturing an image gets its own intuitive function name whereas recording sound does not. But even more frustration that on my Mac I get this:

SystemDialogInput["RecordSound"]
SystemDialogInput::unsupt: "The \!\(\"RecordSound\"\) dialog type is not currently supported on this platform. "

Edit 2

Thanks for the frame by frame type capture solutions posted below but I was hoping for a more direct (native) solution -- even if undocumented -- that would be analogous to me just controlling QuickTime from within Mma (which can be done).

As for recording sound, does anyone know why SystemDialogInput["RecordSound"] isn't supported on Macs and what potential methods exist for Mac?

thanks

Mike

Edit 3

In Version 9 SystemDialogInput["RecordSound"] works on Macs.

Answer 1

vid[time_, frame_] := Module[{tag},
  Reap[Do[Sow[CurrentImage[], tag];
     Pause[frame], {Round[time/frame]}]][[2, 1]]]

So, vid[1., 0.001] would return a list of snapshots taken every 0.001 seconds over a second.

This opens a dialog that allows you to record sound and returns it as a Sound object

SystemDialogInput["RecordSound"]; 

Answer 2

SystemDialogInput["RecordSound"] will bring up a dialog that let's you record sound. It works both on Windows and Mac in v9, but only on Windows in earlier versions. It doesn't work on Linux.

But what if you need to record sound without user interaction, and you want to avoid a modal dialog? The right way is to use some external and documented tool (e.g. sox), but I happened to try to dissect the "RecordSound" dialog, and here are the results. These may be Mac-specific.

On Mac, I believe some sort of initialisation may be needed, but I'm not entirely sure. Evaluating

FrontEndExecute[FrontEnd`RecordSound[7, 0]]
FrontEndExecute[FrontEnd`RecordSound[8, 0]]

will probably do this. This is the least clear point so far. This may not be needed on Windows.

Now,

• FrontEndExecute[FrontEnd`RecordSound[5]] will list the available devices by number
• FrontEndExecute[FrontEnd`RecordSound[6, deviceNumber]] will list the available formats for the device
• FrontEndExecute[FrontEnd`RecordSound[1, deviceNumber, formatNumber]] will start recording. It returns control immediately.
• FrontEndExecute[FrontEnd`RecordSound[2]] will stop recording and return the duration.
• FrontEndExecute[FrontEnd`RecordSound[3]] will return the recorded sound (it's the "OK" button in the dialog)
• FrontEndExecute[FrontEnd`RecordSound[4]] will probably discard the recorded sound (it's the Cancel button)
• FrontEndExecute[FrontEnd`RecordSound[9, 0]] will return the current volume of the recorded sound, and is used for the progress indicator in the dialog.

Warning: This functionality is undocumented, and not meant for end users. I'm just guessing at how it works. There's a real risk that playing with these will crash your front end, mess up its internal state or will cause a memory leak. Use at own risk.

Answer 3

You can use CurrentImage and set up a ScheduledTask to capture frames at the desired fps. Something like:

frames = {};
fps = 30;
task = CreateScheduledTask[frames = {CurrentImage[], frames};, 1/fps];

Then start and stop recording with

StartScheduledTask[task];
StopScheduledTask[task];

Note that stopping the task won't turn off the camera on a Mac (don't know about other systems). In order to turn it off, you'll have to execute IMAQ`StopCamera[]

Finally, to play the video back, run

ListAnimate[Reverse@Flatten@frames, fps]

---

Re: sound, SystemDialogInput["RecordSound"]; as Rojo pointed out is the way to go. However, this does not work on a mac and I'm not aware of an easy way to do it. You could perhaps interface with java to record sound, but I don't know anything about it.

Answer 4

I used the answer above to create a small function to grab a bit of sound using the default microphone on my computer.

 Clear[recordTime];
recordTime[t_: 1] := 
 Module[{device = FrontEndExecute[FrontEnd`RecordSound[5]]},
  FrontEndExecute[FrontEnd`RecordSound[1, Keys[First[device]], 1]];
  Pause[t];
  FrontEndExecute[FrontEnd`RecordSound[2]];
  FrontEndExecute[FrontEnd`RecordSound[3]]]

This function could easily be extended to control which microphone (if multiple devices were present) and which format to use.

I am using a Mathematica 10 on Windows 8.

NOTE: I really wanted to upvote the answer that gave me the information I needed here, but i'm new and i don't have enough "reputation" to vote yet.

Answer 5

For a GUI experience, you can use VideoCapture[] and AudioCapture[]. If you want to have programmatic control to streams from your camera or microphone, You can look into VideoRecord[] and AudioRecord[]