Points on circle equally spaced

Question

This might be a really simple question, but how do you generate equally spaced points on a circle? I have looked here and here, have played around for ages - I am sure I am missing something very obvious :/ Here does it, but is there anything more straightforward?

Obviously

ParametricPlot[{Sin[x], Cos[x]}, {x, -π, π}]

plots it, and

cplot[m_] := g1 = (d = (q = 100;
  f = (lop = 
     Transpose[{Flatten[
        Reverse[
          Table[Gamma[y], {y, 0, q}]] /. {ComplexInfinity -> m}], 
       Flatten[Table[x^n, {n, 0, q}]]}];
    {#1*#2} & @@@ lop);
  Flatten[f];
  Total[f]);
sol = Solve[d == 0];
r = ListPlot[{{Re@x, Im@x} /. sol}, AspectRatio -> Automatic, 
  PlotStyle -> Black];
Show[r, Axes -> False, ImageSize -> 800]);
Show[cplot[#] & /@ Range[1]]

is a roots example, but was after something simpler.

I had worked that much out ... just have a Mathematica mental block :/ — martin, Mar 25 '14 at 23:16
Many functions' roots do it - just wanted a nice simple way to do it :/ — martin, Mar 25 '14 at 23:17
Incidentally, is there a way of curling n points into a circle, or any other shape without ParametricPlot or PolarPlot? — martin, Mar 25 '14 at 23:21
@martin Re curling....Perhaps this could be modified: http://mathematica.stackexchange.com/questions/20004/subdividing-a-polygon-equivalent-fractions/20063#20063 — Michael E2, Mar 25 '14 at 23:58
@ Michael - this is what I was after - many thanks for your imparting your knowledge of previous posts! — martin, Mar 26 '14 at 00:06

score 1 · Answer 1 · answered Mar 25 '14 at 23:15

1

Using ListPolarPlot you can do the following:

r = 1;
points = 6;
angle = 2 π / points;
Show[
    ParametricPlot[{r * Sin[x], r * Cos[x]}, {x, -π, π}],
    ListPolarPlot[Table[{angle * n, r}, {n, 1, points}], PlotStyle->{Black, PointSize[Large]}]
]

answered Mar 25 '14 at 23:15

Tyilo

1,545
13
25

Great - thank you! I'm sure I will be kicking myself in a minute :/ – martin Mar 25 '14 at 23:18
ListPolarPlot - Great! :) – martin Mar 25 '14 at 23:19
Is there any way of converting these points to data that a regular ListPlot can plot? – martin Mar 25 '14 at 23:38

m_goldberg · Accepted Answer · 2014-03-26T00:48:16.283

1

Here is a rather general solution to your problem. It produces a list of the coordinates of n regularly spaced points on a circle centered at {cx, cy} with radius r, where the initial point is rotated counterclockwise from the x-axis by initθ radians (defaults to 0).

validNum = Except[_Complex, _?NumericQ];
regSpacedPts[center : {cx : validNum, cy : validNum : 0}, r : validNum, 
             n_Integer /; n > 0, initθ : validNum] :=
  Table[center + r {Cos[# + initθ], Sin[# + initθ]} &[N[ 2 π k/n]], {k, 0, n - 1}]

Here is an application.

With[{xy = {1/4., 3/2}, r = .5, n = 5, θ = 90 °}, 
  Graphics[{Circle[xy, r], 
            PointSize[Large], Point[regSpacedPts[xy, r, n, θ]], 
            Red, Point[xy]},
    PlotRange -> {{-1/4, 3/4}, {1, 2}},
    Frame -> True,
    PlotRangePadding -> .1]]

5-points

edited Mar 26 '14 at 00:48

answered Mar 26 '14 at 00:15

m_goldberg

107,779
16
103
257

OK, this gives me loads of things to study - 'Chop,WithandExcept` I am still unsure of - will give them a go - again - many thanks. – martin Mar 26 '14 at 00:24
@martin. Chop is a bit of fussiness on my part. You could probably remove it without any harm. The validNum pattern uses Except to exclude complex numbers from being used as arguments. – m_goldberg Mar 26 '14 at 00:29
1

@martin. I made some corrections you will want to attend to. I removed Chop (really not needed) and I stopped an extra copy of first point from being generated. This code was taken from some code It wrote to generate regular polygons, which used the extra point to close the polygon, something not needed for your application. – m_goldberg Mar 26 '14 at 00:45

Points on circle equally spaced

2 Answers2