Adding 1 to all second elements

Question

I want to add 1 to all second elements but I am running into a "level" problem I believe here is my code:

list2 = {{{5, 1}}, {{2, 1}, {3, 1}}, {{7, 1}}, {{2, 3}}}

r1pow = Map[(# + {{0, 1}}) &, list2]

the result I got is:

{{{5, 2}}, {{0, 1}} + {{2, 1}, {3, 1}}, {{7, 2}}, {{2, 4}}}

my desired result is:

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

as you can see it is giving a problem for my second element {{2, 1}, {3, 1}}, how can i fix this problem?

list2[[All, All, 2]] = list2[[All, All, 2]] + 1 or shorter list2[[All, All, 2]]++ — ciao, Apr 28 '14 at 00:08
Before hitting the site with similar questions please take the time to understand the answers to your earlier ones. — Mr.Wizard, Apr 28 '14 at 00:28

score 8 · Accepted Answer · answered Apr 28 '14 at 00:09

8

One way:

list2 = {{{5, 1}}, {{2, 1}, {3, 1}}, {{7, 1}}, {{2, 3}}};
list2 /. {a_Integer, b_Integer} :> {a, b + 1}

(* {{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}} *)

answered Apr 28 '14 at 00:09

Michael E2

235,386
17
334
747

score 7 · Answer 2 · edited Apr 13 '17 at 12:55

7

I closed this question a few minutes ago, but I just reopened it because I see that you are specifically asking about fixing your code rather than how to perform a certain operation. You can use this:

Map[# + {0, 1} &, list2, {2}]

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

I removed the extraneous set of brackets
I added a levelspec of {2}

In recent versions you should also be able to use MapAt which would be somewhat cleaner:

MapAt[# + 1 &, list2, {All, All, 2}]

Usually faster however is to use the methods you have already been shown by Kuba and now rasher, and discussed further in Elegant operations on matrix rows and columns. I still suspect that this question would not have been asked if you properly understood that method.

edited Apr 13 '17 at 12:55

Community

1

answered Apr 28 '14 at 00:36

Mr.Wizard

271,378
34
587
1,371

what method are you speaking of? – Crisp Apr 28 '14 at 00:48
1

@Crisp Sorry, I thought that was clear. I mean using Part as in list2[[All, All, 2]]++ or list2[[All, All, 2]] += 7. Please look at the documentation for Part, Increment, and AddTo. My preference for Part is explained here. – Mr.Wizard Apr 28 '14 at 03:37
ok thank you very much, will do. – Crisp Apr 28 '14 at 04:32

score 3 · Answer 3 · answered Dec 10 '23 at 13:52

Showing some of the newer functions

list = {{{5, 1}}, {{2, 1}, {3, 1}}, {{7, 1}}, {{2, 3}}};

1.

ReplaceAt (new in 13.1)

ReplaceAt[list, x : {a_, b_} :> {a, b + 1}, {All, All}]

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

2.

Threaded (new in 13.1)

# + Threaded[{0, 1}] & /@ list

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

3.

ApplyTo (new in 12.2)

If we want to change the original list inline:

list //= MapAt[# + {0, 1} &, {;; , ;;}];
list

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

score 3 · Answer 4 · answered Dec 10 '23 at 14:39

3

Supporting @eldo in an effort of good house maintenance as much as I can.

We can use Query

Query[All, {1 -> ( # + {0, 1} &)}]@list

{{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}}

answered Dec 10 '23 at 14:39

bmf

15,157
2
26
63

score 2 · Answer 5 · answered Dec 10 '23 at 15:51

2

Using Cases and Map:

list2 = {{{5, 1}}, {{2, 1}, {3, 1}}, {{7, 1}}, {{2, 3}}};
Cases[list2, x_ :> First@Map[{#[[1]], #[[2]] + 1} &, {x}, {2}]]
({{{5, 2}}, {{2, 2}, {3, 2}}, {{7, 2}}, {{2, 4}}})

answered Dec 10 '23 at 15:51

E. Chan-López

23,117
3
21
44

Adding 1 to all second elements

5 Answers5