appending element to sub list

Question

I have a list of the form:

lstA = { 
         { {"a","b"}, -1.5}, 
         { {"c","d"}, -2  }   
       }

I wanto to add another value to each sublist that comes from another list

lstB = {-5,-10}

I would like the final list to look like

 mergeList =  { 
            { {"a","b"}, -1.5, -5 }, 
            { {"c","d"}, -2,-10 }
            }

I have tried using Append to get each sublist, and then append the value corresponding value from lstB:

  Append[{#1, #2} & @@@ lstA, lstB]

I have been trying Append. Append should work because I want to get each sublist then append the value from lstB — olliepower, Apr 29 '14 at 16:19

Artes · Accepted Answer · 2014-04-29T19:05:07.940

The most efficient approach uses (new in ver.6) ArrayFlatten:

ArrayFlatten[{{lstA, Transpose[{lstB}]}}]

{{{"a", "b"}, -1.5, -5}, {{"c", "d"}, -2, -10}}

Instead of threading Append which is not very efficient, another much faster way would use also Transpose twice and Append only once:

Transpose @ Append[ Transpose @ lstA, lstB]

or alternatively one could exploit the second argument of Join using Transpose only once:

Join[ lstA, Transpose[{lstB}], 2]

In the Front-end Transpose can be is rewritten (using Esc+ tr + Esc) in especially terse (neat) way, e.g.:

enter image description here

Moreover we have:

enter image description here

score 6 · Answer 2 · answered Apr 29 '14 at 16:19

6

You can do that using MapThread:

mergeList = MapThread[Append, {lstA, lstB}]

answered Apr 29 '14 at 16:19

celtschk

score 2 · Answer 3 · answered Apr 29 '14 at 16:29

2

Since I like to stick with my ideas, here is an example with Insert:

Insert[lstA[[#1]], #2, #3] & @@@ Thread[{Range@Length@lstA, lstB, {3, 3}}]

{{{"a", "b"}, -1.5, -5}, {{"c", "d"}, -2, -10}}

answered Apr 29 '14 at 16:29

Öskå

3 Answers3