Labeling a grid

Question

I have

m = {{0, -1, -2, -3, -4}, {1, 0, -1, -2, -3}, {2, 1, 0, -1, -2}, {3, 
    2, 1, 0, -1}, {4, 3, 2, 1, 0}};

And a grid Grid[m,Frame->All]

I would like to label the grid such that every column has a number above it and every row has a number to its side. This is what I've currently managed to do.

Labeled[Grid[m,Frame->All],{Y:{1,5},X:{1,5}},{Left,Top}]

How can I label the grid appropriately?

I highly recomment this answer by Mike Honeychurch but if you do not need such interface take a look at Headings option for TableForm. You can allways add such heading as a new column and row, then you have to read adding columns/rows. — Kuba, May 02 '14 at 08:32

ubpdqn · Answer 1 · 2014-05-02T08:49:27.637

7

You could use TableForm, e.g.

col = CharacterRange["A", "E"];
row = CharacterRange["a", "e"];
TableForm[m, TableHeadings -> {row, col}]

A way using Grid:

Grid[{PadLeft[col, 6, ""]}~Join~
  MapThread[PadLeft[#1, 6, #2] &, {m, row}], 
 Dividers -> {{False, True, {False}}, {False, True, {False}}}]

enter image description here

edited May 02 '14 at 08:49

answered May 02 '14 at 08:35

ubpdqn

60,617
3
59
148

score 7 · Accepted Answer · answered May 02 '14 at 10:15

7

Perhaps what you want:

m = Array[Subtract, {5, 5}, 0];
r = Range @ 5;

Grid[
 ArrayFlatten[{{"", {r}}, {{r}\[Transpose], m}}],
 Frame -> All
]

enter image description here

answered May 02 '14 at 10:15

Mr.Wizard

271,378
34
587
1,371

Exactly what I was looking for. +1 For simplicity. – pyler May 02 '14 at 10:19

Labeling a grid

2 Answers2

Linked