Getting unevaluated function expression

Question

Say I've got a function f[x_] := a x^2 + b*x + c; and later set for some other reason a=1; how can I get the expression of f in an untouched form (with "a" and not "1")?

I don't want to use HoldForm or Unevaluated in definition of f nor parse Definition[f].

An example code that I'm trying to modify, so that it ignores evaluation of symbols in the first 2 StylePrints.

SetAttributes[DD, HoldFirst];
DD[f_, var_] := HoldForm[\!\(\*SubscriptBox[\(\[PartialD]\), \(var\)]f\)];

SetAttributes[CSE, HoldFirst];
CSE[e_] := 
  ToExpression[
   If[StringFreeQ[ToString[HoldForm@e], "Subscript["], 
    "\[CapitalDelta]" <> ToString[HoldForm@e] <> "", 
    StringReplace[ToString[HoldForm@e], 
     "Subscript[" -> "Subscript[\[CapitalDelta]"]], TraditionalForm, 
   HoldForm];

SetAttributes[TDE, HoldFirst];
TDE[fun2_, vars2__] := 
  Sqrt[Sum[i, {i, ((CSE[#] DD[fun2, #])^2) & /@ vars2}]];

SetAttributes[TotalDiffrentialError, HoldFirst];
TotalDiffrentialError[fun_, vars__] := Module[{Expanded},
   StylePrint[CSE[fun] == TDE[fun, vars], "EquationNumbered"];
   StylePrint[CSE[fun] == FullSimplify[ReleaseHold[TDE[fun, vars]]], 
    "EquationNumbered"];
   FullSimplify[ReleaseHold[TDE[fun, vars]]]];

So what I'm trying to do with that is to print elegant equations without numerical values, up to a certain point when (in current implementation) I release all the Holds. This design would in theory let me to define values somewhere before and not bother about passing them to the function.

Answer 1

On CSE

If you want to work with symbolic representation of changes in functions or variables you probably don't want that object (cse) to evaluate to something wrapped in HoldForm with parts modified with "Subscript[" -> "Subscript[\[CapitalDelta]" rule.

(BTW, it's not even clear what is the result of it. CSE[x] // FullForm looks very weird, for example: there is no space between CapitalDelta and x, and it's not even interpreted as a proper expression when inside HoldForm. It's quite alarming, IMO.) I get it now, sorry. CSE@x is a new symbol, x written with greek prefix. Arguably, mixing greek and latin in symbols names is not a proper way to go—certainly so if the core reason for this is pretty printing, which I suspect is the case.

If you just want changes in variables pretty printed then I promise you will enjoy MakeBoxes:

MakeBoxes[cse[Subscript[x_, sub_]], opt_] ^:= 
SubscriptBox[
  RowBox@{"\[CapitalDelta]", MakeBoxes[x, opt]}
, MakeBoxes[sub, opt]]

MakeBoxes[cse[x_], opt_] ^:= 
RowBox@{"\[CapitalDelta]", MakeBoxes[x, opt]}

It looks like this:

In[1]:= cse[Subscript[x, 1]]
Out[1]= Subscript[\[CapitalDelta] x, 1]

On global variables

As Leonid Shifrin noted in comments, definitions with global variables in the rhs are shortcuts to disasters of all sorts. If you want to leave as much as possible non-localized, and also avoid HoldForm and Unevaluated, I suspect solutions will invariably turn out to be rather weird:

In[2]:= SetAttributes[f, HoldRest]

In[3]:= f[x_, leadingCoeff : _ : a] := 
        With[{cachedA = a}, 
        Clear@a; ({leadingCoeff x^2 + b x + c, 
        Hold[a = cachedA] /. Hold@Set[v_, v_] :> (## &[])}) /. {f_} :> f]

In[4]:= f@x
Out[4]= c + b x + a x^2

In[5]:= a = 1
Out[5]= 1

In[6]:= ReleaseHold@f@x /. {first_, ___} :> HoldForm@first
Out[6]= c + b x + a x^2

In[7]:= a
Out[7]= 1

I don't suggest you use this, of course (you'd have to wrap instances of f@x in ReleaseHold to not lose the value of a), I merely hope this will help you convince yourself to localize everything, and don't reject quoting. The only alternative seems to be a flood of [often unpredictable] side effects.