Adding elements to a collection of lists

Question

I would like to add element a at the start of a series of lists.

For example I have a collection of lists called

LISTS1 = {{1,2,3,4,5},{2,3,4,5,6},{3,4,5,6,7},{4,5,6,7,8}}

Now I want to add a 0 to the beginning of the first list, two 0s to the second list and so on, to get:

{{0,1,2,3,4,5},{0,0,2,3,4,5,6},{0,0,0,3,4,5,6,7},{0,0,0,0,4,5,6,7,8}}.

I suspect this needs to be done using the Prepend command in combination with something to change the numbers of elements to add for each individual list in the collection.

Chris Degnen · Answer 1 · 2012-04-27T18:07:57.523

10

This would be a neat way to do it:

LISTS1 = {{1, 2, 3, 4, 5}, {2, 3, 4, 5, 6}, {3, 4, 5, 6, 7}, {4, 5, 6, 7, 8}};

MapIndexed[Join[Table[0, #2], #1] &, LISTS1]

{{0, 1, 2, 3, 4, 5}, {0, 0, 2, 3, 4, 5, 6}, {0, 0, 0, 3, 4, 5, 6, 7}, {0, 0, 0, 0, 4, 5, 6, 7, 8}}

edited Apr 27 '12 at 18:07

answered Apr 27 '12 at 09:21

Chris Degnen

30,927
2
54
108

score 7 · Answer 2 · answered Apr 27 '12 at 09:22

One possibility without particular attention to performance:

Sample input:

data = {{1, 2, 3, 4, 5}, {2, 3, 4, 5, 6}, {3, 4, 5, 6, 7}, {4, 5, 6, 7, 8}}

Let's generate the zeros ...

zeros = ConstantArray[0, #] & /@ Range@Length[data]

... and prepend them to the sublists:

MapThread[Join, {zeros, data}]

score 7 · Answer 3 · answered Apr 27 '12 at 16:59

7

This is how I would do it:

Table[Join[Table[0, {j, i}], LISTS1[[i]]], {i, Length[LISTS1]}]

answered Apr 27 '12 at 16:59

mohit6up

281
1
4

score 7 · Answer 4 · answered Apr 27 '12 at 17:03

7

A variation of Szabolcs's method with extra speed and infix! ;-)

list = {{1, 2, 3, 4, 5}, {2, 3, 4, 5, 6}, {3, 4, 5, 6, 7}, {4, 5, 6, 7, 8}};

Join[
 0 ~ConstantArray~ # & ~Array~ Length@list,
 list,
 2
]

answered Apr 27 '12 at 17:03

Mr.Wizard

271,378
34
587
1,371

1

Naughty naughty... a gem for the infixionado.Strong stuff ;-) – Yves Klett Apr 27 '12 at 17:56
3

Horrible, horrible to read. However, it has the advantage that ConstantArray returns a packed array, and using the third argument of Join is always nice. – rcollyer Apr 27 '12 at 18:21

score 6 · Answer 5 · answered Apr 27 '12 at 16:00

6

A slight variation of Chris's answer:

LISTS1 = {{1, 2, 3, 4, 5}, {2, 3, 4, 5, 6}, {3, 4, 5, 6, 7}, {4, 5, 6, 7, 8}};

MapIndexed[ArrayPad[#1, {First[#2], 0}] &, LISTS1]

answered Apr 27 '12 at 16:00

J. M.'s missing motivation

124,525
11
401
574

kglr · Answer 6 · 2012-04-27T18:54:54.907

5

Two variations of MapThread and MapIndexed:

MapThread with PadLeft:

  MapThread[PadLeft[#1, #2 + Length@#1] &, {LISTS1,Range@Length[LISTS1]}]

MapIndexed with PadLeft:

   MapIndexed[PadLeft[#, #2 + Length@#1] &, LISTS1]

edited Apr 27 '12 at 18:54

answered Apr 27 '12 at 16:03

kglr

394,356
18
477
896

score 4 · Answer 7 · edited Apr 27 '12 at 16:23

4

A slight variant:

Join[ ConstantArray[0, #], LISTS1[[#]]] & /@ Range@Length@LISTS1

giving

(* {{0, 1, 2, 3, 4, 5}, {0, 0, 2, 3, 4, 5, 6}, {0, 0, 0, 3, 4, 5, 6, 7}, 
    {0, 0, 0, 0, 4, 5, 6, 7, 8}} *)

edited Apr 27 '12 at 16:23

rm -rf

88,781
21
293
472

answered Apr 27 '12 at 11:42

user1066

17,923
3
31
49

score 3 · Answer 8 · answered Jul 22 '13 at 07:54

3

ls = {{1, 2, 3, 4, 5}, {2, 3, 4, 5, 6}, {3, 4, 5, 6, 7}, {4, 5, 6, 7, 8}};
Join[0 Range@Range@Length@ls, ls, 2]

(*{{0, 1, 2, 3, 4, 5}, {0, 0, 2, 3, 4, 5, 6}, {0, 0, 0, 3, 4, 5, 6, 7},
  {0, 0, 0, 0, 4, 5, 6, 7, 8}}*)

answered Jul 22 '13 at 07:54

chyanog

15,542
3
40
78

Adding elements to a collection of lists

8 Answers8

Linked