Row and Column Headings for a Grid

Question

It would be useful for me if I could write:

Grid[{{a, b}, {c, d}, {e, f}}, 
 GridHeadings -> {{"r1", "r2", "r3"}, {"c1", "c2"}}]

just like

TableForm[{{a, b}, {c, d}, {e, f}}, 
 TableHeadings -> {{"r1", "r2", "r3"}, {"c1", "c2"}}]

except that I don't want the two lines TableForm produces.

How could I add this additional option to Grid?

I think it is a duplicate but I can't find it. Meanwhile I'm linking great answer by Mike Honeychurch. — Kuba, Jun 03 '14 at 06:08
It is worth to mention that TableForm is based on GridBox and we can see the "definition" of TableForm by evaluating: FormatValues[TableForm]. — Alexey Popkov, Jun 03 '14 at 06:14
IMHO, it's probably best practice not to override the built-in functions if it's not necessary. — Myridium, Jun 03 '14 at 06:22
this is 3 years old but may be of interest: http://ibnhconsulting.blogspot.com.au/2011/06/styling-tables-in-mathematica.html — Mike Honeychurch, Jun 03 '14 at 07:58
@Mike - Great link ! I am already working with "tables.nb"-features. — eldo, Jun 03 '14 at 09:38
For what it's worth, if you wish to convert the answers below to emulate the Option syntax you requested please see: Functions with Options — Mr.Wizard, Jun 03 '14 at 12:08

Nasser · Answer 1 · 2014-06-03T06:21:51.980

3

I do not know of options that would do this to Grid. Grid is really just matrix with extra options build-in.

Can you just build-it in manually?

fillInHeader[h_, data_] := Module[{n, grid},
   n = Length[data];
   grid = Table[Null, {n + 1}, {n}];
   grid[[2 ;; -1, All]] = h[[1]];
   grid[[1, 2 ;; -1]] = h[[2]];
   grid[[2 ;; -1, 2 ;; -1]] = data;
   grid
   ];
headings = {{"r1", "r2", "r3"}, {"c1", "c2"}};
data = {{a, b}, {c, d}, {e, f}};
Grid[fillInHeader[headings, data]]

Mathematica graphics

If you want to add other Grid options, you can now do this

Grid[fillInHeader[headings, data], Frame -> All]

Mathematica graphics

You can use it with GraphicsGrid also

 GraphicsGrid[fillInHeader[headings, data], ImageSize -> 100]

Mathematica graphics

etc...

edited Jun 03 '14 at 06:21

answered Jun 03 '14 at 06:08

Nasser

143,286
11
154
359

using your code above: why shouldn't it be posssible to unprotect "Grid" and add it as an option? – eldo Jun 03 '14 at 06:16
@eldo, I would not know how to do this. I also think making a simple function to fill-in the headers on the sides of the data is just simpler than what you suggest. – Nasser Jun 03 '14 at 06:19

score 3 · Answer 2 · answered Jun 03 '14 at 06:40

data = {{a, b}, {c, d}, {e, f}};
headings = {{"r1", "r2", "r3"}, {"c1", "c2"}};

Grid[Prepend[Flatten /@ Transpose[{headings[[1]], data}], 
             PadLeft[headings[[2]], Length@data[[1]] + 1, ""]]]

enter image description here

I assume data sublists of same length, if not the case, more work needed as this (and other answers so far) will give goofy results.

score 3 · Accepted Answer · answered Jun 03 '14 at 07:00

3

data = {{a, b}, {c, d}, {e, f}};
head = {{"r1", "r2", "r3"}, {"c1", "c2"}};


Join[Transpose[{Join[{""}, head[[1]]]}], Join[head[[{2}]], data], 2] // Grid

answered Jun 03 '14 at 07:00

Kuba

136,707
13
279
740

I am very pleased. "MyGrid[d_, h_] := Join[Transpose[{Join[{""}, h[[1]]]}], Join[h[[2]], d], 2] // Grid" now easily gives me what I wanted. Just flipped an acceptance coin between rasher and you. – eldo Jun 03 '14 at 07:26
3

@eldo: In the future, please use Mathematica's RandomInteger for such decisions: I've seen coins with Kuba's face on both sides... ;-) – ciao Jun 03 '14 at 07:32

score 1 · Answer 4 · answered Jul 15 '15 at 13:00

1

Here's another idea that makes use of ArrayFlatten

 GridPlus[data_, headers_, opts : OptionsPattern[Grid]] := 
 Grid[ArrayFlatten[{{{{""}}, {headers[[1]]}}, \
 {Transpose[{headers[[2]]}], data}}], opts]

answered Jul 15 '15 at 13:00

Seth Chandler

3,132
14
25

Row and Column Headings for a Grid

4 Answers4

Linked