How to control the layering of graphics displayed with Show

Question

I am trying to combine two graphics objects using Show.

The first one is an isosurface:

data = Import["/PATH/furan-ks.sdat", "Table"];
ALEE = Nearest[data[[All, {1, 2, 3}]] -> Rescale[data[[All, 4]]]];
cfALEE = ColorData["Rainbow"]@First@ALEE[{#1, #2, #3}] &;
isosurface=ListSurfacePlot3D[data[[All, {1, 2, 3}]], BoxRatios -> Automatic, 
ColorFunction -> cfALEE, ColorFunctionScaling -> False, 
Boxed -> False, Axes -> False, Mesh -> None, MaxPlotPoints -> 25, 
ImageSize -> 500]

isosurface

The second one is a sequence of points:

 geom = Import["/PATH/furan.geom", "Table"];
 AngToAu = 1.88971616463;
 Function[x, x*AngToAu];
 geom = Map[%, geom, {2}];
 Show[Graphics3D[{Black, PointSize[0.05], Point[geom]}, Boxed -> False]]

points

I want the points to appear on the same plot as the surface and be plotted at the appropriate scale. A command I am using:

Show[isosurface, Graphics3D[{Black, PointSize[0.05], Point[geom]}, Boxed -> False]]

The catch is that the points effectively appear inside the surface and are NOT visible. I need to somehow project them on the surface or make them visible through the surface.

How do I deal with this? Any suggestions?

EDIT: attached the files isosurface geom

You could make Tubes out of it? I'm afraid that you should provide the code for the isosurface and the points so one can reproduce it. — Öskå, Jun 11 '14 at 11:00
Have you looked at the Opacity directive for the code that generates isosurface? — m_goldberg, Jun 11 '14 at 12:31
you may use Overlay and SetAlphaChannel Overlay[{isosurface, SetAlphaChannel[ Graphics3D[{Black, PointSize[0.05], Point[geom]}, Boxed -> False], .5]}, All, 2] — s.s.o, Jun 11 '14 at 14:00
http://mathematica.stackexchange.com/questions/3665/can-2d-and-3d-plots-be-combined-so-that-the-2d-plot-is-the-bottom-surface-of-the — george2079, Jun 11 '14 at 16:31
@molkee What exactly would you wish? A see through solution? A Tube solution? One could also simply put the points on the surface.. :) — Öskå, Jun 11 '14 at 18:50
@Öskå can you paste your code for the Tube solution here? — molkee, Jun 11 '14 at 18:55
@molkee In the mean time, if you are hurry: {# - {4, 0, 0}, # + {4, 0, 0}} & /@ geom; Show[Graphics3D[Tube[#, 0.1] & /@ %], isosurface] — Öskå, Jun 11 '14 at 19:00
@Öskå thanks a lot! I need something to get done asap, you are right! — molkee, Jun 11 '14 at 19:05
Well, if you want the see-through solution just add PlotStyle -> Opacity@.5 to ListSurfacePlot3D. — Öskå, Jun 11 '14 at 19:23
Use spheres instead of points. They will poke through the surface. — rhomboidRhipper, Jun 11 '14 at 22:30
@molkee That's what I thought :) I'm glad to help but it's also good sometimes to get credits from it :) — Öskå, Jun 18 '14 at 19:48

score 2 · Accepted Answer · answered Jun 12 '14 at 11:56

Here is what I would propose:

AngToAu = 1.88971616463;
geom = AngToAu*Import["~/Downloads/furan.geom", "Table"];
pts = Show[
   Graphics3D[{Black, PointSize[0.05], Point[geom]}, Boxed -> False]];

data = Import["~/Downloads/furan-ks.sdat", "Table"];
ALEE = Nearest[data[[All, {1, 2, 3}]] -> Rescale[data[[All, 4]]]];
cfALEE = ColorData["Rainbow"]@First@ALEE[{#1, #2, #3}] &;
data = data[[All, {1, 2, 3}]];
isosurface = 
  ListSurfacePlot3D[data, BoxRatios -> Automatic, Boxed -> False, 
    Axes -> False, Mesh -> None, MaxPlotPoints -> 25, ImageSize -> 250, 
    RegionFunction -> Function[{x, y, z}, 
      And @@ (Norm[{y - #[[2]], z - #[[3]]}] >= .4 & /@ geom)], 
    PlotStyle -> Opacity@.5]

Producing your shell with holes as a projection of geom thanks to RegionFunction:

Then, you can either add your points:

Show[pts, isosurface]

Mathematica graphics

or create Tubes out of them:

points = Cases[Normal[isosurface], Line[x__] :> x, \[Infinity]];
centers = Mean /@ (Select[#, First@# > 0 &] & /@ points /. {{} -> Sequence[]});
coorTube = {# - {First@#2, 0, 0}, # + {First@#2, 0, 0}} & @@@ 
  Thread@{SortBy[geom, Last], SortBy[centers, Last]};
Show[
  Graphics3D[{White, Opacity@.5, Tube[#, 0.4] & /@ coorTube}, Boxed -> False],
  pts, isosurface]

Mathematica graphics

score 1 · Answer 2 · answered Jun 12 '14 at 17:48

Quick and dirty, rasterize the 3d and overlay a 2d graphic:

     Show[{Rasterize[ 
           Show[ExampleData[{"Geometry3D", "Torus"}], ViewPoint -> {0, 0, 1}] ,
                ImageSize -> {400, 400}], Graphics[Disk[125 {Sin[2 # Pi/6],
                     Cos[2 # Pi/6]} + {200, 200}, 20] & /@ Range[6]]}]

enter image description here

How to control the layering of graphics displayed with Show

2 Answers2