Merge two lists for List3DPlot

Question

I have a two lists: list1 = {{x1, y1}, {x2, y2}, {x3, y3}, {x4, y4}, {x5, y5}} and list2 = {z1, z2, z3, z4, z5} and I want to make a third one like this output = {{x1, y1, z1}, {x2, y2, z2}, {x3, y3, z3}, {x4, y4,z4}, {x5, y5, z5}} What nice command can do the trick? It is to do a ListPlot3D with two lists with more than 10000 entries. I tried with Map and pure function but it is giving me troubles. Thank you

You want to add a column to the existing matrix. Try to look for such statement in old posts here. — Kuba, Jun 13 '14 at 15:32
I recommend taking a look at ArrayReshape, see e.g. this question How to partition a list in a specific way? — Artes, Jun 13 '14 at 15:54
What is the most effective way to add rows and columns to a matrix — andre314, Jun 13 '14 at 15:56

kglr · Answer 1 · 2014-06-13T16:19:47.043

3

Transpose[Join @@ {Transpose@list1, {list2}}]

or

Join @@@ Transpose[{list1, List /@ list2}]

or

Transpose[{Sequence @@ Transpose@list1, list2}]

or

ArrayReshape[{list1, list2}, Dimensions[list1] + {0, 1}]

(* {{x1,y1,z1},{x2,y2,z2},{x3,y3,z3},{x4,y4,z4},{x5,y5,z5}} *)

edited Jun 13 '14 at 16:19

answered Jun 13 '14 at 16:01

kglr

394,356
18
477
896

score 2 · Accepted Answer · answered Jun 13 '14 at 15:31

2

Try this

Transpose@{list1[[All,1]],list1[[All,2]],list2}

or this

MapThread[{#1[[1]], #1[[2]], #2} &, {list1, list2}]

answered Jun 13 '14 at 15:31

molekyla777

2,888
1
14
28

Thanks, I will use the MapThread, it is nice! – lambertmular Jun 13 '14 at 16:08

score 2 · Answer 3 · answered Jun 13 '14 at 16:47

2

With the last parameter of Join:

Join[list1, List /@ list2, 2]

answered Jun 13 '14 at 16:47

eldo

67,911
5
60
168

score 2 · Answer 4 · answered Jun 13 '14 at 18:10

2

Flatten /@ MapThread[List, {list1, list2}]

or

MapThread[Append, {list1, list2}]

or

Thread[f[list1, list2]] /. f -> Append

answered Jun 13 '14 at 18:10

Basheer Algohi

19,917
1
31
78

score 1 · Answer 5 · answered Jun 13 '14 at 16:49

1

Here is another one, with MapIndexed

 MapIndexed[ {list1[[Last@#2,1]],list1[[Last@#2,2]],#1},list2]

answered Jun 13 '14 at 16:49

lalmei

3,332
18
26

Merge two lists for List3DPlot

5 Answers5