Tracking iterations of a function

Question

I'm learning MMA with Wagner's book. On page 41, he uses this to display the iterative steps of a FindRoot. However, I can't seem to replicate this (code at end), perhaps due to the difference in MMA versions (his was MMA 3.0!). Using Trace doesn't seem to help; it just displays the final value of x.

Codes:

FindRoot[Print[x]; Sin[x] - Cos[x], {x, 0.5}]
Trace[FindRoot[Sin[x] - Cos[x], {x, 0.5}]]

Edit I have also tried to use his method--Print[x] within a function--for an exercise in the section and that seems to work (though with some quirk in the result). EvaluationMonitor also works, and frankly I find the latter much more intuitive. Below is my solution for the problem (code at end); I'm not sure if this is the way Sin[x] is actually sampled, so any feedback is very welcome.

Plot[Sin[x], {x, \[Pi]/4, \[Pi]/2}] // InputForm
Plot[Print[x]; Sin[x], {x, \[Pi]/4, \[Pi]/2}]
Reap[Plot[Sow[x]; Sin[x], {x, \[Pi]/4, \[Pi]/2}]][[2]]
{plot, List@stepValue} = 
  Reap[Plot[Sin[x], {x, \[Pi]/4, \[Pi]/2}, 
    EvaluationMonitor :> Sow[x]]];
stepValuePoints = {stepValue, Sin[stepValue]} // Transpose;
ListPlot[stepValue, AxesLabel -> {Step, x}]
Manipulate[
 Show[
  (* Actual y = Sin[x] curve *)
  Plot[Sin[x], {x, \[Pi]/4, \[Pi]/2}, PlotStyle -> Yellow],
  (* Generated mesh points *)
  ListPlot[stepValuePoints, PlotStyle -> Red],
  (* Arrow tail *)
  ListLinePlot[{Table[stepValuePoints[[i]], {i, step - 5, step - 1}]}],
  (*Arrow head *)
  Graphics@{Blue, 
    Arrow[{stepValuePoints[[step - 1]], stepValuePoints[[step]]}]},
  PlotRange -> {{\[Pi]/4, \[Pi]/2}, {Sqrt[2.]/2, 1}}], {step, 6, 
  Length[stepValuePoints], 1}]
anim = Table[
   Show[
    (* Actual y = Sin[x] curve *)
    Plot[Sin[x], {x, \[Pi]/4, \[Pi]/2}, PlotStyle -> Yellow],
    (* Generated mesh points *)
    ListPlot[stepValuePoints, PlotStyle -> Red],
    (* Arrow tail *)
    ListLinePlot[{Table[
       stepValuePoints[[i]], {i, step - 5, step - 1}]}],
    (*Arrow head *)
    Graphics@{Blue, 
      Arrow[{stepValuePoints[[step - 1]], stepValuePoints[[step]]}]},
    PlotRange -> {{\[Pi]/4, \[Pi]/2}, {Sqrt[2.]/2, 1}}], {step, 6, 
    Length[stepValuePoints], 1}];
Export["anim.gif", anim, "DisplayDurations" -> 0.25]

Answer 1

EvaluationMonitor works in this case (per b.gatessucks' helpful suggestion). StepMonitor also works although it doesn't display the starting value.

Code

FindRoot[Sin[x] - Cos[x], {x, 0.5}, 
 EvaluationMonitor :> Print["x=", x, ", y=", Sin[x] - Cos[x]]]

FindRoot[Sin[x] - Cos[x], {x, 0.5}, 
 StepMonitor :> Print["x=", x, ", y=", Sin[x] - Cos[x]]]

Answer 2

EvaluationMonitor (and StepMonitor) have been mentioned, but not every function has these options. So here's a more general way:

You need to prevent the function from evaluating for non-numeric arguments. This is a very very common issue described here among other places.

Solution 1:

f[x_?NumericQ] := (Print[x]; Sin[x] - Cos[x])

FindRoot[f[x], {x, .5}]

Solution 2:

I don't always like to define a new function for a one-time-use scenario. I quite like David Bailey's When function suggested here, and I have it (as well as some variations) in my personal toolbox.

FindRoot[When[NumericQ[x], Print[x]; Sin[x] - Cos[x]], {x, .5}]

---

There's yet another way, specific to FindRoot (as well as many plotting functions). use Evaluated -> False:

FindRoot[Print[x]; Sin[x] - Cos[x], {x, .5}, Evaluated -> False]

Answer 3

If you are also interested in easy way of viewing the points on figure, you can also use

<< Optimization`UnconstrainedProblems package.

This package runs the optimization function (like FindRoot), keeps track of the function and gradient evaluations and steps taken during the search (using the EvaluationMonitor and StepMonitor options), and shows them superimposed on a plot of the function.

<< Optimization`UnconstrainedProblems`
FindRootPlot[Sin[x] - Cos[x], {x, 0.5}, ImageSize -> 600, 
 PlotRange -> {-0.5, 0.1}]