Unexpected result from FullSimplify

Question

In the following simplification why doesn't Mathematica get a zero when asked to compute "Y-Z" eventually?

 a = 1 - 4 A Q^2; 
 b = (-972 + 648) A Q^2 + 54;
 c = 9 - 36 A Q^2; 

 Y = 12 Q/( 
 Sqrt[A] (  
   2 - (3 2^(1/3) a )/(Sqrt[b^2 - 4 c^3] + b  )^(1/3)  - ( 
       Sqrt[b^2 - 4 c^3] + b  )^(1/3)/( 3 2^(1/3) )     )   );

 Z = (4/A) + (3 2^(1/3) a )/(A (Sqrt[b^2 - 4 c^3] + b  )^(1/3) )  +  ( 
  Sqrt[b^2 - 4 c^3] + b  )^(1/3)/( 3 2^(1/3) A);

Q = Sqrt [ 3/(16 A)];
Y - Z // FullSimplify
(-9 + 4 Sqrt[3] Sqrt[1/A] Sqrt[A])/(2 A)

One can do the above calculation by hand and one would see that for the specific chosen value of $Q = \sqrt{3/16 A}$ one would get $Y = Z = \frac{3}{A}$. Why doesn't Mathematica see this?

And is there a way to get Mathematica to detect if there are other values of $Q$ where $Y = Z$? (..I found this one value special value of $Q$ by just staring at the equation for sometime...)

Rewriting the functions again.

$Y = \frac{12Q}{\sqrt{A}\sqrt{ 2 - \frac{3 (2^{1/3})a }{(\sqrt{b^2 - 4 c^3 } + b )^{1/3} } - \frac{(\sqrt{b^2 - 4 c^3 } + b )^{1/3} }{3 (2^{1/3})} } }$

$Z = \frac{1}{A} \left (4 + \frac{(\sqrt{b^2 - 4 c^3 } + b )^{1/3} }{3 (2^{1/3})} + \frac{3 (2^{1/3})a }{(\sqrt{b^2 - 4 c^3 } + b )^{1/3} }\right ) $

at the chosen values of $Q = \sqrt{\frac{3}{16A} }$ one has $a = \frac{1}{4}$ and $b = - \frac{27}{4}$ and $b^2 - 4 c^3 = 0$. Also whenever I encounter $b^{1/3}$ I am writing that as $-3 \times 2^{-2/3}$. Substituting these into the above one gets $Y = Z = \frac{3}{A}$

You can try $Assumptions = {A > 0}; Y - Z // FullSimplify but it seems there is a mistake somewhere. — Kuba, Jun 26 '14 at 10:28
Getting $\frac{4 \sqrt{3} \sqrt{\frac{1}{A}} \sqrt{A}-9}{2 A}$ and with assuming A > 0 $\frac{4 \sqrt{3}-9}{2 A}$. No Zero. — Phab, Jun 26 '14 at 10:36
@Phab But did you do the calculation by hand? Isn't it zero doing so? — Student, Jun 26 '14 at 11:35
@Phab I am quite confident that it is zero. (there are other cross-checks which it passes given the larger context fro where it comes) It would be great if you could kindly check again. — Student, Jun 26 '14 at 13:09
It is not zero. {FullSimplify[Y //. {Q -> Sqrt[3/(16 A)], A -> 1}] // N, FullSimplify[Z //. {Q -> Sqrt[3/(16 A)], A -> 1}] // N} gives {3.4641, 4.5} so here is at least one value of A for which the two are not equal. — bill s, Jun 26 '14 at 13:31
FullSimplify[Y, Assumptions -> A > 0] gives (2 Sqrt[3])/A and FullSimplify[Z, Assumptions -> A > 0] gives 9/(2 A) for Q = Sqrt[3/(16 A)], so your confidence that Y - Z = 0 is misplaced. — m_goldberg, Jun 26 '14 at 14:34
@m_goldberg I am not sure whats going on here - do you agree or disagree with the intermediate steps that i have typed above? (below "Rewriting the functions..") — Student, Jun 26 '14 at 14:38
@bills Can you kindly see the intermediate steps that I have written above? — Student, Jun 26 '14 at 14:49
Using your formulas Y /. A -> 1 // N // Chopyields 3.4641 while Z /. A -> 1 // N // Chopyields 4.5. These two figures are not equal. — Alexei Boulbitch, Jun 26 '14 at 14:50
"whenever I encounter b^1/3 I am writing that as −3×2^(−2/3)". That is incorrect. b^(1/3) is -9/4. — m_goldberg, Jun 26 '14 at 15:08
@m_goldberg I don't know what you mean. $(-3)^3 = - 27$ and $2^2 = 4$ — Student, Jun 26 '14 at 15:26
Shouldn't your expression Y = 12 Q/(Sqrt[A] (...)) be Y = 12 Q/Sqrt[A (...)]? — m_goldberg, Jun 26 '14 at 16:59
This is closely related if not a duplicate: Strange behavior of Reduce with a cubic equation. — Artes, Jun 27 '14 at 15:12

m_goldberg · Answer 1 · 2014-06-26T18:37:22.033

The problem is that b^(1/3) has three roots. You are choosing the real root, -(3/2^(2/3)), while Mathematica is choosing, (3 (-1)^(1/3))/2^(2/3) which is complex. To get the result you want, rewrite your expressions for Y and Z like this:

Y =
  12 Q/
    Sqrt[A (2 - 
            (3 2^(1/3) a)/Surd[Sqrt[b^2 - 4 c^3] + b, 3] - 
            Surd[Sqrt[b^2 - 4 c^3] + b, 3]/(3 2^(1/3)))];

Z = (4/A) + (3 2^(1/3) a)/A /Surd[Sqrt[b^2 - 4 c^3] + b, 3] + 
   Surd[Sqrt[b^2 - 4 c^3] + b, 3]/(3 2^(1/3) A);

With the above you will get

FullSimplify[Y - Z, Assumptions -> A > 0]

Unexpected result from FullSimplify

1 Answers1