How can I append associations with uneven elements?

Question

My dataset is pretty simple so far:

Questions = Dataset[{
<|"Statement" -> "What is the capital of Switzerland?", "Answer" -> "Bern", 
"Incorrect Answers" -> {"Zurich", "Berlin", "Vienna"}|>,
<|"Statement" -> "Who is the king of the jungle?", "Answer" -> "Lion", 
"Incorrect Answers" -> {"Giraffe", "Mouse", "Monkey"}|>,
<|"Statement" -> "2+2?" , "Answer" -> "4", "Incorrect Answers" -> {"15", "13", "1e15"}|>}]

If I try the following, everything goes right:

NewQuestion1 = <|"Statement" -> "To be...", "Answer" -> "or not to be", 
"Incorrect Answers" -> {"or to eat", "continued", "dummy"}|>;
Append[Questions, NewQuestion1]

Nevertheless, if I delete the dummy answer of the NewQuestion, it will not work:

NewQuestion2 = <|"Statement" -> "To be...", "Answer" -> "or not to be", 
"Incorrect Answers" -> {"or to eat", "continued"}|>;
Append[Questions, NewQuestion2]

This issue seems weird since you can declare a data set with uneven lists from the beginning:

Questions = Dataset[{
   <|"Statement" -> "What is the capital of Switzerland?", 
    "Answer" -> "Bern", 
    "Incorrect Answers" -> {"Zurich", "Berlin", "Vienna"}|>,
   <|"Statement" -> "Who is the king of the jungle?", 
    "Answer" -> "Lion", 
    "Incorrect Answers" -> {"Giraffe", "Mouse", "Monkey"}|>,
   <|"Statement" -> "2+2?" , "Answer" -> "4", 
    "Incorrect Answers" -> {"15", "13", "1e15"}|>,
   <|"Statement" -> "To be...", "Answer" -> "or not to be", 
    "Incorrect Answers" -> {"or to eat", "continued"}|>
   }]

Any suggestions on how to append NewQuestion2 and/or explanations of why this error is happening?

Answer 1

Well, here is a workaround:

First, we load the package TypeSystem:

Needs["TypeSystem`"]

Now we define the Dataset to expect any type:

Questions = 
 Dataset[{<|"Statement" -> "What is the capital of Switzerland?", 
    "Answer" -> "Bern", 
    "Incorrect Answers" -> {"Zurich", "Berlin", "Vienna"}|>, <|
    "Statement" -> "Who is the king of the jungle?", 
    "Answer" -> "Lion", 
    "Incorrect Answers" -> {"Giraffe", "Mouse", "Monkey"}|>, <|
    "Statement" -> "2+2?", "Answer" -> "4", 
    "Incorrect Answers" -> {"15", "13", "1e15"}|>}, 
  Vector[Struct[{"Statement", "Answer", "Incorrect Answers"}, {AnyType, AnyType, AnyType}]]]

Note the undocumented second argument of Dataset

We can now append with no problems:

NewQuestion2 = <|"Statement" -> "To be...", "Answer" -> "or not to be", 
   "Incorrect Answers" -> {"or to eat", "continued"}|>;

Then

Append[Questions, NewQuestion2]