Prime-palindromic number selected from a list

Question

I want to find all prime-palindromic numbers up to 5000. Prime-palindromic numbers are numbers that themselves and their reverse digits are both primes. For example, 31 is a prime-palindromic number because both 31 and 13 are prime. Here is my code, but it somehow does not work.

 Select[Range@5000, PrimeQ[Join[FromDigits[Reverse[IntegerDigits[#]]], # ]] &]

Answer 1

Here you code

Select[Range@5000,(PrimeQ[#]&&PrimeQ[FromDigits[Reverse[IntegerDigits[#]]]])&]

Answer 2

Let's see where you went wrong:

• Join[a,b] is not {a,b}, you have to type Join[{a},{b}] if you want to use Join in this way.
• The second argument of Select is a criterion function, it needs to return either true or false. Your function returns a list of boolean values instead. You need to check if all values in the list are true, so you need to use And.

Improvements of style:

• Instead of Join[{a},{b}] you can simply write {a,b}.
• Prefix notation (f@expr) can make your code look simpler.

Code:

Select[Range@5000, And @@ PrimeQ@{FromDigits@Reverse@IntegerDigits@#, #} &]

Answer 3

You can also use Reap and Sow:

Reap[If[PrimeQ[FromDigits[Reverse@IntegerDigits[#]]], Sow[#]] & /@ 
Select[PrimeQ][Range[5000]]][[2, 1]]

Or more concisely as per comment by @bmf:

Reap[If[PrimeQ[IntegerReverse[#]], Sow[#]] & /@ Select[PrimeQ][Range[5000]]][[2, 1]]

Answer 4

Just rephrasing the accepted answer with the help of a function:

Clear[primePalindromicQ];
primePalindromicQ[n_ /; n ∈ PositiveIntegers] := 
 PrimeQ[n] && PrimeQ@FromDigits@Reverse@IntegerDigits@n

Usage:

Select[primePalindromicQ][Range[5000]]

Answer 5

About using Scan instead of Map when using Reap and Sow in @bmf's proposal

Using Map when using Reap and Sow:

(*My mate @bmf*)
Reap[If[PrimeQ[IntegerReverse[#]], Sow[#]] & /@ 
Select[PrimeQ][Range[5000]]][[2, 1]] // RepeatedTiming // First
(0.00932226)

UsingScan when using Reap and Sow:

Reap[Scan[If[PrimeQ[IntegerReverse[#]], Sow[#]] &, 
Select[Range[5000], PrimeQ]]][[2, 1]] // RepeatedTiming // First
(0.0087359)

The times obtained above using RepeatedTiming for both Map and Scan are quite similar, indicating that the efficiency of both methods is comparable for this data size. It's important to note that the real advantage of using Scan instead of Map in this context is to avoid creating an unnecessary intermediate list, but the actual improvement in execution time may be minor.

That said, the choice to use Scan instead of Map in this case is not just about efficiency. It is also a design choice that reflects the intent of the code. By using Scan, we indicate that the list of results produced by applying the function doesn't matter and that only the side effect is of interest (in this case, the seeding process with Sow).

In practice, for problems of this size, the execution time difference between Map and Scan is smaller. However, as the problem scales or is integrated into more complex code, these design decisions can have more significant implications for both efficiency and readability.