Where to see all Mathematica units

Question

Is there a tutorial page that have all Mathematica units? I sometimes have hard time figuring out the correct unit spelling when using quantities

You could check out: http://reference.wolfram.com/language/guide/Units.html — user85503, Sep 03 '14 at 16:23
You can use a query to WolframAlpha to discover units for a particular application, e.g., WolframAlpha["units for volume"] or WolframAlpha["SI units"] — Bob Hanlon, Sep 03 '14 at 17:09
also of note: http://reference.wolfram.com/language/Compatibility/tutorial/Units.html — Nick Lariviere, Sep 09 '14 at 13:21

score 26 · Accepted Answer · edited Nov 11 '22 at 09:09

26

This should list you all available units in Mathematica.

Needs["QuantityUnits`"]    
Keys[QuantityUnits`Private`$UnitReplacementRules]

Inspired by eldo I made a little dynamic interface:

Needs["QuantityUnits`"]
table = Keys[QuantityUnits`Private`$UnitReplacementRules];
Panel[DynamicModule[{f = ""}, 
  Column[{Text[Style["Mathematica Unit Search:", Bold]], 
    InputField[Dynamic[f], String, ContinuousAction -> True], 
    Dynamic[Union@Flatten[StringCases[#, ___ ~~ f ~~ ___] & /@ table] // 
      TableForm]}]]]

enter image description here

edited Nov 11 '22 at 09:09

alexchandel

155
5

answered Sep 03 '14 at 16:23

paw

5,650
23
31

2

Notice the typo: "FeetfRainfall" (reported to Support) – paw Sep 03 '14 at 18:13
That panels make Mathematica 10 crash if pressing "panel format" in the suggestion bar. Can anybody confirm that please? – rhermans Sep 04 '14 at 12:28
1

Can confirm! (Windows 7 64-bit, MMA10) – paw Sep 04 '14 at 13:23
Thanks for the confirmation. I'm Not in front of a proper computer now, I will file a report in a few hours unless somebody else does it before me. – rhermans Sep 04 '14 at 13:27
Do that! Funny how this answer revealed a typo and a bug. – paw Sep 04 '14 at 13:30
Here it is: http://mathematica.stackexchange.com/q/58868 – rhermans Sep 04 '14 at 17:33

eldo · Answer 2 · 2014-09-04T12:20:52.730

Expanding a little bit on paw's nice discovery:

Needs["QuantityUnits`"]    
table = Keys[QuantityUnits`Private`$UnitReplacementRules];

Since this table is very long one can restrict the output, f.e. with

Union @ Flatten[StringCases[#, "Feet" ~~ ___] & /@ table] // TableForm

enter image description here

UPDATE

A similar question could arise with the more than 1000 inbuilt formula names:

formulas = FormulaLookup[All];

Find all formulas including "speed":

(speed =
   Union@Flatten[
     StringCases[#, ___ ~~ "speed" ~~ ___, IgnoreCase -> True] & /@
      formulas]) // Multicolumn

enter image description here

Extract those with FormulaData:

(inter = Intersection[FormulaData[], speed]) // Multicolumn

enter image description here

TraditionalForm@
 Framed[Grid[{#, FormulaData[#]} & /@ inter,
   Dividers -> All,
   Spacings -> {{2, 2}, 3},
   Alignment -> Left,
   BaseStyle -> {FontFamily -> "Helvetica"},
   Background -> {None, {{Hue[.6, .15, .9], GrayLevel[.9]}}},
   FrameStyle -> Directive[Thick, White]
   ],
  FrameMargins -> 0.5,
  FrameStyle -> GrayLevel[.7]]

enter image description here

Where to see all Mathematica units

2 Answers2

Linked