Find arc length

Question

I am trying to find the arc length for

enter image description here

using

n = 2; f[x_] := -2 Re[ExpIntegralEi[(ZetaZero[n]) Log[x]]] Log[x]/ Sqrt[x]
a = Quiet[FindMinimum[f[x], {x, 1.4}]];
b = Quiet[FindMaximum[f[x], {x, 1.7}]];
Plot[f[x], {x, (x /. a[[2]]) - 0.1, (x /. b[[2]]) + 0.1}, 
Epilog -> {Red, PointSize[Medium], Point[{{x /. a[[2]], a[[1]]},
{x /. b[[2]], b[[1]]}}]}, ImageSize -> 300]

arc = NIntegrate[ Sqrt[1 + D[f[x], x]^2], {x, (x /. a[[2]]), (x /. b[[2]])}]

Am I doing something silly?

@Chenminqi, I Googled "Mathematica arc length" but only ArcLengthFactor came up!! :/ — martin, Sep 15 '14 at 15:10
If you define f sans Re[], and then use Re[] on the max, min, plot, and NIntegrate, they will all work. As it stands, D has trouble with the Re because it is not an analytic function. — Daniel Lichtblau, Sep 15 '14 at 18:38
Strongly related Wolfram Community thread: "Computing arch length of a spline curve." — Alexey Popkov, Oct 28 '14 at 19:26

george2079 · Accepted Answer · 2014-09-15T18:38:20.573

5

Based on @RunnyKine's comment the trouble is with Re. It seems there should be a more elegant way to do this, but moving the Re outside the differential does the job:

 da[x_] = Sqrt[1 +
     (Re@D[(-2 (ExpIntegralEi[(ZetaZero[n]) Log[x]]) Log[x]/Sqrt[x]),x])^2  ]
 NIntegrate[da[x], {x, x /. a[[2]], x /. b[[2]]}]

.308277

Also, yet another line measure approach:

 Total[Norm /@ 
     Differences@
          Table[{x, f[x]}, {x, (x /. a[[2]]), (x /. b[[2]]), .0001}]]

0.308216

edited Sep 15 '14 at 18:38

answered Sep 15 '14 at 16:31

george2079

38,913
1
43
110

Great - should have thought of that ! Thanks - should be a little more accurate :) – martin Sep 15 '14 at 16:54

RunnyKine · Answer 2 · 2014-09-15T16:40:51.950

4

If you just plot the region of the graph you're interested in:

pl = Plot[f[x], {x, (x /. a[[2]]), (x /. b[[2]])}, 
  Epilog -> {Red, PointSize[Medium], Point[{{x /. a[[2]], a[[1]]}, {x /. b[[2]], b[[1]]}}]}, 
  ImageSize -> 300, PlotPoints -> 500]

Mathematica graphics

Then, you can do:

ArcLength @ DiscretizeGraphics @ pl

0.30827679

edited Sep 15 '14 at 16:40

answered Sep 15 '14 at 15:06

RunnyKine

33,088
3
109
176

great - thank you :) I searched for "Mathematica arc length" but only ArcLengthFactor came up! ... Any ideas why direct integration won't work? Am I missing something silly? – martin Sep 15 '14 at 15:09
1

@martin, let me look into that. – RunnyKine Sep 15 '14 at 15:12
1

@martin, if you evaluate D[f[x], x] by itself, you'll see where the problem is. You have a derivative of Re term left in there and I don't think Mathematica knows what to do with that. – RunnyKine Sep 15 '14 at 15:26
Ah great - OK, thanks! – martin Sep 15 '14 at 15:43
Cute, but how accurate is this? Does it just count pixels? If so, there are only two digits one can really trust. (I don't know what the OP is looking for, but I usually want more than two digits from my computations). – Igor Rivin Sep 15 '14 at 15:47
@IgorRivin I wouldn't recommend this method since it produces quite large errors, see two highest score answers to this question Finding length of intersection of two surfaces. – Artes Sep 15 '14 at 15:54
@Artes that was DiscretizeRegion with ImplicitRegion and if you scroll down in the link you provided and look at the answer using DiscretizeGraphics you'll realize that the error does not apply here. – RunnyKine Sep 15 '14 at 15:57
@IgorRivin, the answer to your question is no, it doesn't just count pixels. – RunnyKine Sep 15 '14 at 15:58
@RunnyKine Nevermind, I wouldn't worry if one provided traditional numerical results. – Artes Sep 15 '14 at 15:59
You can specify PlotPoints->some big number if you are concerned about the accuracy – george2079 Sep 15 '14 at 16:37
@george2079, nice suggestion. I added that. – RunnyKine Sep 15 '14 at 16:41

score 3 · Answer 3 · answered Sep 15 '14 at 16:21

Or Create an interpolation function from the plot and calculate its arc length. Note that I have modified the definitions of a and b.

n = 2; f[x_] := -2 Re[ExpIntegralEi[(ZetaZero[n]) Log[x]]] Log[x]/Sqrt[x]
a = FindArgMin[f[x], {x, 1.4}][[1]] // Quiet;
b = FindArgMax[f[x], {x, 1.7}][[1]] // Quiet;

plt = Plot[f[x], {x, a, b}];

f2 = Interpolation[
   Cases[plt, Line[pts_] :> pts, Infinity][[1]]];

arc = NIntegrate[Sqrt[1 + f2'[x]^2], {x, a, b}]

0.308277

Thanks for the solution - will give it a go in a bit :) – martin Sep 15 '14 at 16:55 — martin, Sep 15 '14 at 16:55

score 1 · Answer 4 · answered Jul 23 '22 at 15:25

In general, one may find the arc length of a graph of f[x] with ArcLength[{x, f[x]}, {x, a, b}] since V10.0, although its robustness improves (hopefully) with age. In this case, the difficulty is Re[] in f[x], and Re[z] is not a differentiable function of a complex variable. However, Re[g[x]] can be a differentiable function of a real variable x. The next problem is that ComplexExpand does not work in this case, as recommended in the documentation for Re (see "Possible Issues"). Thus, I am thrown back onto basic principles, namely, use the definition of the derivative, which will be found defining fp[x] below. Now we have to get ArcLength to use it. To do this, we need to prevent f[x] from evaluating. It would be nice if it were defined as f[x_?NumericQ]; however, while that's convenient for this purpose, it is often inconvenient for other purposes. But we can easily temporarily redefine f[] this way as done below, while also defining the derivative of f[x]. (The limit could be done inside Block; but (1) I wanted to show the result and (2) since it takes so long, it's nice to do it once and save the result. Actually, the result is partially cached, so recomputing gets faster.)

fp[x_] = (* takes 13+ sec. *)
 Limit[(f[x + h] - f[x])/h, h -> 0, Assumptions -> x > 0] // 
  FullSimplify
(*
x^(-(3/2) - ZetaZero[2]) *
  (-x - x^(2 ZetaZero[2]) + 
   x^ZetaZero[2] (-2 + Log[x]) Re[ExpIntegralEi[Log[x] ZetaZero[2]]])
*)
Block[{f, y = f[x]},
 f /: HoldPattern[D[f[x], x]] = fp[x];
 f[x_?NumericQ] = y;
 ArcLength[{x, f[x]}, {x, (x /. a[[2]]), (x /. b[[2]])}]
 ]
(*  0.308277  *)

Find arc length

4 Answers4

Linked