Vertical (mis-)aligning of plotmarkers and legend text in V10 PlotLegends

Question

Consider this example, taken from the docs and modified for a larger font size using Style (V10.0):

ListPlot[Table[f, {f, {Sin[x], Cos[x]}}, {x, 0, 2 π, 0.1}],
PlotLegends -> (Style[#, 40] & /@ {"sin(x)", "cos(x)"})]

Mathematica graphics

The plot markers are clearly aligned at the bottom of the legend text, which does not seem optimal.

Is there a way to influence this aligning?

@Mr. Wizard a true \[Pi] serial edit - my bad for being lazy :D — Yves Klett, Sep 17 '14 at 14:12

kglr · Accepted Answer · 2014-09-20T23:14:24.413

15

ListPlot[Table[f, {f, {Sin[x], Cos[x]}}, {x, 0, 2 π, 0.1}],
PlotLegends ->PointLegend[ (Style[#, 40] & /@ {"sin(x)", "cos(x)"}),Alignment->Center]]

enter image description here

Update: As noted by rcollyer in the comments Alignment is an undocumented option for PointLegend. As an alternative, the following old Pane trick works without relying on an undocumented option:

ListPlot[Table[f, {f, {Sin[x], Cos[x]}}, {x, 0, 2  π, 0.1}],
PlotLegends ->(Style[Pane[#, BaselinePosition -> Center],40]& /@ 
              {"sin(x)", "cos(x)"})]
(* same picture *)

Update 2: Works with ListLinePlot and LineLegend combination:

ListLinePlot[Table[f, {f, {Sin[x], Cos[x]}}, {x, 0, 2 π, 0.1}], 
 PlotLegends -> LineLegend[(Style[#, 40] & /@ {"sin(x)", "cos(x)"}), Alignment -> Center]]

enter image description here

edited Sep 20 '14 at 23:14

answered Sep 17 '14 at 14:00

kglr

394,356
18
477
896

Can we extend that to ListLinePlot as well? – Yves Klett Sep 17 '14 at 14:05
2

As a side note, Alignment is an undocumented option for PointLegend. – rcollyer Sep 17 '14 at 14:05
Just checked - works nicely with an otherwise identical ListLinePlot. – Yves Klett Sep 17 '14 at 14:25
For my sins, I forgot to accept ... – Yves Klett Apr 14 '16 at 14:14
1

One note here: in order to have it so that the labels aren't also centered (as they are in this answer), you need to separate out the horizontal and vertical alignments: Alignment -> {Automatic, Center}. – AnInquiringMind Feb 13 '20 at 17:05

score 6 · Answer 2 · edited Sep 17 '14 at 14:10

6

A reasonable workaround is to use SwatchLegend with LegendMarkers set:

ListPlot[
 Table[f, {f, {Sin[x], Cos[x]}}, {x, 0, 2 π, 0.1}],
 PlotLegends -> 
  SwatchLegend[{"sin(x)", "cos(x)"}, LabelStyle -> 40, LegendMarkers -> "Bubble" ]
]

enter image description here

edited Sep 17 '14 at 14:10

Mr.Wizard

271,378
34
587
1,371

answered Sep 17 '14 at 14:01

rcollyer

33,976
7
92
191

1

Thank you! Should the current aligning be considered as buggy in this case? And can we extend the aligning for ListLinePlot legends as well? – Yves Klett Sep 17 '14 at 14:06

Vertical (mis-)aligning of plotmarkers and legend text in V10 PlotLegends

2 Answers2

Linked