Finding the surface area of a 3D convex hull

Question

I have noted several instances here and here where ConvexHullMesh, introduced in v10 has been used to greatly simplify some geometry problems. Determining the volume of a region encompassing a set of 3D points, pts is now simply:

Volume@ConvexHullMesh@pts

Is there an equally simplified method for determining the surface area of this convex hull?

Note, the documentation for ConvexHullMesh suggests that the area can be obtained, using RegionMeasure, however I suspect this is a typo, since RegionMeasure gives an area only if the points have a dimension of 2.

score 13 · Accepted Answer · 2014-10-25T19:39:29.787

13

Area@RegionBoundary@ConvexHullMesh@pts

For example, consider a cube, which has volume 1 and surface area 6:

pts = Tuples[{0, 1}, 3];
convexHull = ConvexHullMesh[pts];
convexHullSurface = RegionBoundary[convexHull];
RegionMeasure[convexHull, #] & /@ {0, 1, 2, 3}
(* {∞, ∞, ∞, 1.} *)
RegionMeasure[convexHullSurface, #] & /@ {0, 1, 2, 3}
(* {∞, ∞, 6., 0} *)

edited Oct 25 '14 at 19:39

answered Sep 23 '14 at 19:20

Nice - I was heading down that road, but took a wrong turn at some point. – bobthechemist Sep 23 '14 at 19:31

RunnyKine · Answer 2 · 2014-09-25T16:02:21.750

11

Here is another way to compute the surface area of a 3D convex hull:

SeedRandom[0]
pts = RandomReal[5, {50, 3}];
chull = ConvexHullMesh @ pts;

Then:

Tr @ PropertyValue[{chull, 2}, MeshCellMeasure]

86.8845076

Update

This approach is good because you have access to individual face areas and with PropertyValue you can do cool things like display the values of the areas on the mesh:

PropertyValue[{chull, {2, All}}, MeshCellLabel] = 
        Style[NumberForm[#, 3], Bold, Darker@Red, 15] & /@ 
                    PropertyValue[{chull, {2, All}}, MeshCellMeasure];

Then:

chull

Mathematica graphics

edited Sep 25 '14 at 16:02

answered Sep 23 '14 at 19:54

RunnyKine

33,088
3
109
176

Nice, I should have added benchmarking requirements to my original question just to make it challenging. – bobthechemist Sep 23 '14 at 19:58

RunnyKine · Answer 3 · 2014-09-24T04:18:53.173

10

For fun, here is an approach that uses the graphics generated from the mesh. Lets generate some points:

SeedRandom[0]
pts = RandomReal[5, {50, 3}];
chull = ConvexHullMesh @ pts;

Create a graphics object from it and discretize it:

gr = Graphics3D[GraphicsComplex[MeshCoordinates[chull], {MeshCells[chull, 2]}]];

And here is the area:

Area @ DiscretizeGraphics @ gr

86.8845076

For comparison:

Area @ RegionBoundary @ chull

86.8845076

edited Sep 24 '14 at 04:18

answered Sep 23 '14 at 19:29

RunnyKine

33,088
3
109
176

Always enjoy a "just for fun" approach. – bobthechemist Sep 23 '14 at 19:32
@bobthechemist. yeah, me too. – RunnyKine Sep 23 '14 at 19:34

score 1 · Answer 4 · answered Dec 20 '23 at 06:40

1

As of version 12, April 16,2019:

Using SurfaceArea:

SeedRandom[0]; (* example borrowed from @RunnyKine *)
pts = RandomReal[5, {50, 3}];
Through[{SurfaceArea, Volume}[ConvexHullMesh@pts]]

{86.8845, 64.3916}

The other example:

pts = Tuples[{0, 1}, 3];
Through[{SurfaceArea, Volume}[ConvexHullMesh@pts]]

{6., 1.}

answered Dec 20 '23 at 06:40

Syed

52,495
4
30
85

1

Nice to see that SurfaceArea finally works in this context. Thanks for digging up an old post. – bobthechemist Dec 20 '23 at 13:36

Finding the surface area of a 3D convex hull

4 Answers4