LocatorPane and multiple EventHandlers, PassEventsDown option

Question

Consider the following piece of code from Heike as an ( accepted ) answer on LocatorPane, selecting multiple Locators - Basically the code implements dragging polygons on a LocatorPane.

 DynamicModule[{pts, range, gr, drag, pts0},
  pts = RandomReal[1, {7, 2}];
  range = {1 ;; 4, 5 ;; 7};
  gr = {{Red,  Polygon @ Dynamic @ pts[[ range[[1]] ]]},
        {Blue, Polygon @ Dynamic @ pts[[ range[[2]] ]]}};
  drag = 0;

  Panel[LocatorPane[Dynamic[pts],
    EventHandler[
     Graphics[
      EventHandler[gr[[#1]],
         {"MouseDown" :>
           (drag = #; pts0 = # - MousePosition["Graphics"] & /@ pts[[ range[[#]] ]])}
      ] & /@ {1, 2}, 
      PlotRange -> {{0, 2}, {0, 2}}],
     {"MouseDragged" :> 
       If[drag > 0, pts[[range[[drag]]]] = # + MousePosition["Graphics"] & /@ pts0],
      "MouseUp" :> (drag = 0)},
     PassEventsDown -> True
    ]
  ]]
 ]

If you run this code you'll notice that when a locator's position is on another polygon the locator does not work anymore.

Question: How can the code above be changed so that a click on a locator always works? Why was it necessary to use two two EventHandlers, and what is a good rule to decide on wether to use the PassEventsDown option?

score 9 · Accepted Answer · edited Feb 11 '20 at 06:22

The following code does what you want. It requires that you press shift to move a locator that is being overlapped by a polygon, instead of moving that polygon.

DynamicModule[{pts, range, gr, drag, pts0}, 
 pts = RandomReal[1, {7, 2}];
 range = {Span[1, 4], Span[5, 7]};
 gr = {{Red, Polygon[Dynamic[pts[[range[[1]]]]]]}, {Blue, 
    Polygon[Dynamic[pts[[range[[2]]]]]]}};
 drag = 0;
 Panel[
  LocatorPane[
   Dynamic[pts],
   EventHandler[
    Graphics[
     EventHandler[
        gr[[#]],
        {
         "MouseDown" :> (drag = # Boole[¬CurrentValue["ShiftKey"]];
           pts0 = # - MousePosition["Graphics"] & /@ pts[[range[[#]]]])
         },
        PassEventsDown -> True
        ] & /@ {1, 2},
     PlotRange -> {{0, 2}, {0, 2}}
     ],
    {
     "MouseDragged" :> 
      If[drag > 0, 
       pts[[range[[drag]]]] = # + MousePosition["Graphics"] & /@ pts0],
     "MouseUp" :> (drag = 0)
     },
    PassEventsDown -> True
    ], Enabled -> Dynamic[drag == 0]
   ]
  ]
 ]

Mathematica graphics

I'll first explain the causes of the unwanted behavior and then explain my solution.

At the base of the problem lies the fact that LocatorPane needs to get its own events, the clicks on the pane that (re)set the position of the locators. The 3 (not 2, if you look closely) EventHandlers get priority above the LocatorPane when you click in their elements. If you don't do a PassEventsDown->True LocatorPane won't see the event at all. It'll be eaten up by the handler. However, if you would pass down the event to the LocatorPane it would set a new position for the locator while at the same time the polygon is being dragged. You get a very erratic result.

My solution consists of the following:

Pass the events to LocatorPane by setting PassEventsDown->True in the deepest event handlers
If we have a dragging event, disable the LocaterPane using the option setting Enabled -> Dynamic[drag == 0]
Enable locator actions on overlapped locators by multiplying the drag variable with Boole[¬CurrentValue["ShiftKey"]], which then disables the polygon dragging behavior if the shift key is pressed. Locator dragging can then proceed as normal.

Disabling, of course! - Thank you very much, Sjoerd for the excellent explanation. — nilo de roock, May 27 '12 at 17:44
In that case this fails on v7, unlike Heike's answer referenced in the question. — Mr.Wizard, May 27 '12 at 19:53
Actually, for me the polygons move when using right-click-and-drag. Is this expected? — Mr.Wizard, May 27 '12 at 20:01
@Mr.Wizard Well, I didn't expect that, nor do I think my three modifications to Heike's code would cause that. I checked, but none of the functions involved seem to be upgraded in v8. Could you try removing the three additions from the code I posted and see what a drag-the-polygon does then? BTW you did click inside the polygon, didn't you? — Sjoerd C. de Vries, May 27 '12 at 20:16
"you did click inside the polygon" -- Yes. Please post the version you would like me to test in Chat. — Mr.Wizard, May 27 '12 at 20:20

LocatorPane and multiple EventHandlers, PassEventsDown option

1 Answers1