Applying different functions to different columns of a Dataset

Question

Suppose I have different functions: Total, Mean and Max and the following Dataset

SeedRandom[0]
dataSet = Dataset[AssociationThread[{"a", "b", "c", "d"} -> #] & /@ RandomReal[4, {10, 4}]]

How can I do the following: apply Total to column "b", Mean to column "a" and Max to column "d", in that order without leaving the Dataset i.e. no use of Normal? So the result should be

{22.09, 2.383, 3.765}

Answer 1

The following should work and can be easily extended:

dataSet[Transpose /* ({Total@#[[1]], Mean@#[[2]], Max@#[[3]]} &), {#b, #a, #d} &]

Timings:

dataSet = Dataset[AssociationThread[{"a", "b", "c", "d"} -> #] & /@ RandomReal[4, {1000000, 4}]];

(* RunnyKine *)

dataSet[Transpose /* ({Total@#[[1]], Mean@#[[2]], 
      Max@#[[3]]} &), {#b, #a, #d} &]; // AbsoluteTiming

(* {0.968942, Null} *)


(* ybeltukov faster *)

dataSet @@@ {{Total, #b &}, {Mean, #a &}, {Max, #d &}}; // AbsoluteTiming

   (* {1.218837, Null} *)

(* alancalvitti *)

dataSet[{Query[Total, "b"], Query[Mean, "a"], Query[Max, "d"]}]; // AbsoluteTiming

(* {11.037016, Null} *)

Answer 2

dataSet[{ Query[Total, "b"], Query[Mean, "a"], Query[Max, "d"]}]

Can be adapted to association:

dataSet[<|"total b" -> Query[Total, "b"], 
  "mean a" -> Query[Mean, "a"], "max d" -> Query[Max, "d"]|>]

Answer 3

From the documentation

dataSet[Total, "b"]

22.0943

Therefore

dataSet @@@ {{Total, "b"}, {Mean, "a"}, {Max, "d"}}

{22.0943, 2.38258, 3.76476}

Faster version

dataSet @@@ {{Total, #b &}, {Mean, #a &}, {Max, #d &}}

{22.0943, 2.38258, 3.76476}