I need to move all the variables(x,y,z) to one side of an equality for the equation of a plane

Question

I have 5(x-1)-(y+1)-(z+1)==0. If I use FullSimplify on it it returns 5x==7+x+y. This is not what I want: I want it to return 5x-y-z==7.

Closely related question: Is is possible to have mathematica move all terms to one side of an equation? — Jens, Jun 01 '12 at 15:45

score 3 · Answer 1 · edited Jun 01 '12 at 13:39

3

Try this:

eq = 5 (x - 1) - (y + 1) - (z + 1) == 0
Map[Plus[7, #] &, Expand[eq]]

(*  5 x - y - z == 7  *)

edited Jun 01 '12 at 13:39

answered Jun 01 '12 at 13:35

Alexei Boulbitch

score 3 · Answer 2 · answered Jun 01 '12 at 13:38

3

The following works nicely:

Block[{cf = CoefficientArrays[#]}, Last[cf].Variables[Subtract @@ #] == -First[cf]] &[
       5 (x - 1) - (y + 1) - (z + 1) == 0]

answered Jun 01 '12 at 13:38

score 3 · Answer 3 · answered Jun 01 '12 at 14:45

3

Another option:

expr = 5 (x - 1) - (y + 1) - (z + 1) == 0;
Expand[expr]//.{a_==b:Except[_?NumericQ]:>a-b==0,a___+b_?NumericQ==c_:>Plus@a==c-b}

answered Jun 01 '12 at 14:45

Simon Woods

score 2 · Answer 4 · answered Jun 01 '12 at 13:43

2

One way is

body = 5 (x - 1) - (y + 1) - (z + 1);
(#[[2]].Variables[body] == -1*#[[1]]) &@
Flatten[Normal@CoefficientArrays[{body == 0}, {x, y, z}], 1]

BR

answered Jun 01 '12 at 13:43

PlatoManiac

4 Answers4