RegionMember with some tolerance?

Question

Can I specify some tolerance for the new geometric-computation function?

RegionMember[Line[{{0, 0}, {1, 0}}], {.5, 0}]
(* True *)

While:

RegionMember[Line[{{0, 0}, {1, 10^-100}}], {.5, 0}]
(* False *)

RegionMember[Line[{{0, 0}, {1, 10.^-100}}], {.5, 0}]
(* True *)

RegionMember[Line[{{0, 0}, {1, 10.^-7}}], {.5, 0}]
(* False *)

score 7 · Answer 1 · answered Oct 17 '14 at 10:35

7

This (or an appropriately written variant) works:

myRegionMember[a_, b_] := With[{threshold = 10^-6},
  If[
   RegionDistance[a, b] < threshold,
   True,
   False
   ]
  ]

answered Oct 17 '14 at 10:35

gpap

9,707
3
24
66

score 4 · Accepted Answer · edited Apr 13 '17 at 12:55

4

There's Internal`$EqualTolerance. See How to make the computer consider two numbers equal up to a certain precision and its reference.

Block[{Internal`$EqualTolerance = 9.},
 RegionMember[Line[{{0, 0}, {1, 10.^-7}}], {.5, 0}]
 ]
(* True *)

It's a relative tolerance, whereas gpap's & kguler's answers give absolute ones. The setting above, which is roughly equivalent to Internal`$EqualTolerance = $MachinePrecision - 7, says approximate numbers that agree to seven digits (or differ in at most the last nine) are to be considered equal.

Block[{Internal`$EqualTolerance = $MachinePrecision - 7},
 {1. + 1.0000001*^-7 == 1, 1. + 1*^-7 == 1}
 ]
(* {False, True} *)

edited Apr 13 '17 at 12:55

Community

1

answered Oct 17 '14 at 10:50

Michael E2

235,386
17
334
747

Yes, this, temporarily overriding the equality criteria, if I understand it correctly. – BoLe Oct 17 '14 at 11:18
Upvote for trick.. – yode Apr 05 '17 at 10:33

kglr · Answer 3 · 2014-10-17T13:24:34.047

3

f1 = RegionDistance[#, #2] < #3]&

f1[Line[{{0, 0}, {1, 10.^-7}}], {.5, 0}, 10^-6]
(* True *)

f2 = Chop[RegionDistance[#, #2] ,#3] == 0&

f2[Line[{{0, 0}, {1, 10.^-7}}], {.5, 0}, 10^-6]
(* True *)

edited Oct 17 '14 at 13:24

answered Oct 17 '14 at 11:15

kglr

394,356
18
477
896

score 1 · Answer 4 · edited Apr 13 '17 at 12:55

Following gpap's answer:

Options[regionMember] = {Tolerance -> 0};

regionMember[reg_Line, p : {_?NumberQ, _?NumberQ},
  OptionsPattern[]] :=
 With[{e = OptionValue[Tolerance]},
  If[e == 0, RegionMember[reg, p], RegionDistance[reg, p] < e]]

line = Line[{{0, 0}, {1, 0}}];
ps = {.5, #} & /@ {0, 10^-100, 10.^-16, 10.^-5};

regionMember[line, #] & /@ ps
(* {True, False, False, False} *)

regionMember[line, #, Tolerance -> 10.^-6] & /@ ps
(* {True, True, True, False} *)

RegionMember with some tolerance?

4 Answers4