Partial application of MapThread

Question

Suppose that I have

f[a_, b_, x_] := ...

I'd like to create a list of n pure functions

{f[1, 4, #]&, f[2, 5, #]&, f[3, 6, #]&, ...}

from two lists of length n like

as = {1, 2, 3, ...}
bs = {4, 5, 6, ...}

What can I do?

Given g[a_, b_] = ..., I know that to get {g[1, 4], g[2, 5], g[3, 6], ...} is to use MapThread[g, {as, bs}], but I don't know how to extend this idea to solve the above problem.

score 2 · Accepted Answer · answered Oct 22 '14 at 16:54

2

You're very close to the solution. You already have

as = {1, 2, 3}
bs = {4, 5, 6}

MapThread[g, {as, bs}]

(* ==> {g[1, 4], g[2, 5], g[3, 6]} *)

Now all you need is

g[a_, b_][x_] := f[a, b, x]

Or alternatively write Function[{a, b}, f[a, b, #] &] in place of g in MapThread.

answered Oct 22 '14 at 16:54

Szabolcs

234,956
30
623
1,263

Damn! you can't type so fast :) – Dr. belisarius Oct 22 '14 at 16:55
Alternatively, you could use With to do it for you, MapThread[With[{a = #1, b = #2}, f[a, b, #]&]&, {as, bs}] – rcollyer Oct 22 '14 at 17:19

kglr · Answer 2 · 2014-10-22T20:35:30.850

2

Also:

Transpose[{as, bs}] /. {a_, b_} :> (f[a, b, #] &)
(* {f[1, 4, #1] &, f[2, 5, #1] &, f[3, 6, #1] &} *)

edited Oct 22 '14 at 20:35

answered Oct 22 '14 at 17:57

kglr

394,356
18
477
896

Partial application of MapThread

2 Answers2