Selecting every n-th element from a list

Question

I have a list:

data = {4, 5, 7, 8, 9, 5, 3, 2, 1, 2, 13, 12};

I want to take those elements in the list which are located at equal distances, say, every third element, getting the list {7, 5, 1, 12}. Can anyone suggest a way of doing this for a list having large number of elements.

I would advice for solutions based on extended syntax, which are easier to understand than runes. — rhermans, Oct 24 '14 at 16:49
@Suren Did you follow the links from my answer and read the documentation? — Szabolcs, Oct 24 '14 at 16:49
Now it becomes clear. Thank you everyone for your prompt handling. — Suro, Oct 24 '14 at 16:53
This question is nicely addressed in the documentation: Getting Pieces of Lists. — gwr, Oct 29 '15 at 10:50
how would the code change if you want to take every third number starting on the second element instead of the first? — SPIL, Jan 18 '17 at 09:29

score 38 · Answer 1 · answered Oct 24 '14 at 16:39

38

Please look up Part and Span.

You can use

data[[ ;; ;; n]]

answered Oct 24 '14 at 16:39

Szabolcs

234,956
30
623
1,263

8

This is one of those questions that are easily answered using the documentation and should be closed as such, but at the same time would probably be really useful for new users (if only for the clear question title). – Yves Klett Oct 24 '14 at 19:10
1

@YvesKlett: Could you link to where you found this easily in the documentation? – orome Oct 03 '15 at 19:48
@ raxacoricofallapatorius Fifth entry in https://reference.wolfram.com/language/ref/Span.html – Yves Klett Oct 04 '15 at 08:46
9

Having looked through the documentation, I didn't find it, only after finding this question, I knew what to look for. – gyger Feb 06 '16 at 10:39
@YvesKlett - Out of the hundreds of names for functions, how are we supposed to know that 'span' is what we're looking for? I mean, it doesn't even have a name, it's like part of the list syntax. – Quark Soup Jun 14 '20 at 19:20
@Quarkly werll, it does feature prominently in the Part documentation. On the other side, Mathematica is not really ... parsimonious with new function names, and I keep running into really, really useful functions I did not know about regularly. – Yves Klett Jun 16 '20 at 15:07
My point is: StackExchange/Google is a far more useful resource than Mathematica documentation because it's organized the way humans think about finding solutions. Why would you want to make Stack Exchange a less useful tool? – Quark Soup Jun 16 '20 at 15:20
@Yves I was able to find " ;; " in the mathematica documentation, but I can't understand what it means when you leave a blank in data[[ ;; ;; n]]. The documentation doesn't seem to describe a blank space. Please help. – Chris Nov 04 '20 at 18:07

score 12 · Answer 2 · answered Oct 29 '15 at 09:03

12

I'm surprised that this has not come up:

Last /@ Partition[data, 3]

Before Span (and version 6), I used it a lot.

answered Oct 29 '15 at 09:03

István Zachar

47,032
20
143
291

kglr · Answer 3 · 2017-08-04T17:39:18.707

9

Downsample:

Downsample[array, n ] returns a downsampled version of the array by sampling every n'th element.

Downsample[data, 3]

{4, 8, 3, 2}

Partition with offset

Flatten @ Partition[data, 1, 3]

{4, 8, 3, 2}

edited Aug 04 '17 at 17:39

answered Aug 04 '17 at 16:02

kglr

394,356
18
477
896

Introduced in version 9 and I discover it only now. Definitely the most direct implementation of the answer the OP wanted. – Michael Stern Mar 08 '20 at 13:44

score 9 · Answer 4 · answered Oct 24 '14 at 16:44

9

As well as Part an Span, you could also use Take.

data = {4, 5, 7, 8, 9, 5, 3, 2, 1, 2, 13, 12};
data[[3 ;; -1 ;; 3]]
Take[data, {3, -1, 3}]

Both give

{7, 5, 1, 12}

answered Oct 24 '14 at 16:44

m_goldberg

107,779
16
103
257

score 5 · Answer 5 · answered Oct 24 '14 at 16:54

Your data

data = {4, 5, 7, 8, 9, 5, 3, 2, 1, 2, 13, 12}

Let's say you want every third starting by the second element, that means you want parts {2, 5, 8, 11}. we get those indexes using Range

Range[2, Length[data], 3]

{2, 5, 8, 11}

Now we use this indexes with Part

Part[data, Range[2, Length[data], 3]]

{5, 9, 2, 13}

score 5 · Answer 6 · answered Oct 29 '15 at 10:09

5

Lots of other great answers here but this is another way

Table[data[[i]], {i, 3, Length@data, 3}]

answered Oct 29 '15 at 10:09

dstahr

381
1
3
8

score 1 · Answer 7 · answered Oct 24 '14 at 16:46

1

You can use

data = {4, 5, 7, 8, 9, 5, 3, 2, 1, 2, 13, 12};
sel = Partition[Range[3, Length@data, 3], 1]
Extract[data, sel]

But I'm sure there are shorter ways.

answered Oct 24 '14 at 16:46

Mockup Dungeon

1,854
12
16

Selecting every n-th element from a list

7 Answers7

Linked

Related