In InputField, how to prevent Shift-Return from generating a new cell?

Question

When running the following in a notebook (not a deployed CDF file), it can sometimes be annoying that accidentally pressing Shift-Return breaks out of the user interface:

Panel@DynamicModule[{input = ""}, InputField[Dynamic[input], String]]

I would like to know if one can (programmatically) prevent such a cell from being "evaluated" when Shift-Return is pressed, so that the user stays in the InputField instead of being thrown out of it while seeing a new generated cell appear.

One quick hack is to define a custom evaluator for the cell in which the InputField is, and make it return Null at the end. You can test by setting it to a simple CellEvaluationFunction->(Null& ). — Leonid Shifrin, Jun 05 '12 at 19:19
@LeonidShifrin I tried that, and it's very close because it doesn't generate a new cell. But it still evaluates silently, increases the history counter and puts the cursor in the next line. — Jens, Jun 05 '12 at 19:24
No time to do this myself, but one idea is examining the help browser's docked cell which also has an InputField in it. — Szabolcs, Jun 05 '12 at 19:34
@Szabolcs That sounds like a good idea. Get help from the help browser in an unconventional way... — Jens, Jun 05 '12 at 19:37
@Jens I briefly looked at it and it seems to be defined as a "front end resource" (not sure what that is). The next step would be searching the installation files for this resource (e.g. even the Find window is a notebook that you can examine---and yes, that has an input field too, maybe we don't need to go to the help browser!) ... Okay, I got to sleep now, I need to catch the Venus transit tomorrow at dawn :-) — Szabolcs, Jun 05 '12 at 19:55
Now, all these solutions seem to work for shift+enter but not for my small enter on the number pad... Hummm — Rojo, Jun 05 '12 at 23:49
Found it. What you want is to set Deployed->True in the output cell — Rojo, Jun 06 '12 at 00:26

score 15 · Accepted Answer · edited Aug 25 '16 at 06:49

15

If you notice Mathematica Documentation Center search field is kind of the same thing. And search window from Ctrl-F too. It uses a similar concept to what I'll show. Important thing to know is that EventHandler can track commands from the Mathematica menu. There is an undocumented option HandleShiftReturn and here is a trick I learned from FW:

DynamicModule[{x = ""}, 
  Column[{
    EventHandler[
      InputField[Dynamic[x], String], 
      {{"MenuCommand", "HandleShiftReturn"} :> {},
       {"MenuCommand", "EvaluateCells"} :> {}} (*edit by Kuba, handles Keypad Enter*)
    ], 
    Dynamic[x]
   }]
]

enter image description here

Return works, but Shift-Return does not.

edited Aug 25 '16 at 06:49

Kuba

136,707
13
279
740

answered Jun 05 '12 at 20:43

Vitaliy Kaurov

73,078
9
204
355

Ah, finally: I had been trying to guess what the Menu command for "Evaluate Cells" might be and gave up guessing a while ago... – Jens Jun 05 '12 at 20:47
6

users could be saved a lot of time if all this stuff was documented. – Mike Honeychurch Jun 05 '12 at 23:56
@Vitaliy could you please add whatever you know about events for EventHandler as an answer to this question: http://mathematica.stackexchange.com/questions/6207/how-do-i-find-all-the-possible-events-that-work-with-eventhandler. thanks – Mike Honeychurch Jun 06 '12 at 00:07
1

This also catches Shift+Return but not keypad Return. Is there a way to extend it? – Mr.Wizard Jun 06 '12 at 01:18
1

@Mr.Wizard add {"MenuCommand", "EvaluateCells"} event handler, 47513 – Kuba May 22 '15 at 06:47
@Jens "EvaluateCells" is in fact a valid token but responsible for keypad Enter. – Kuba May 22 '15 at 06:48
@Kuba Thank you! – Mr.Wizard May 22 '15 at 08:42

score 12 · Answer 2 · edited May 23 '17 at 12:35

12

ExpressionCell[Panel@DynamicModule[{input = ""}, InputField[Dynamic[input], String]]]

Mathematica graphics
Content added:

Mathematica graphics

ShiftReturn pressed:

Mathematica graphics

Learned this here.

edited May 23 '17 at 12:35

Community

1

answered Jun 05 '12 at 20:24

Sjoerd C. de Vries

65,815
14
188
323

It works! I also combined it with Mike's answer to a related issue and it still worked in that more complicated setting, too. – Jens Jun 05 '12 at 20:35
@jens Glad to hear. I still find ExpressionCell a somewhat mysterious function. – Sjoerd C. de Vries Jun 05 '12 at 20:44
This catches Shift+Return but not keypad Return. Any comment on that? – Mr.Wizard Jun 06 '12 at 01:17
@Mr.Wizard Sorry, I'm on a laptop without keypad. Can't test. – Sjoerd C. de Vries Jun 06 '12 at 05:28

Rojo · Answer 3 · 2012-06-06T02:03:39.683

This is just adding a Deployed->True to your output cell, and removing the CellEditDuplicate which ruins everything

CellPrint@
  ExpressionCell[
   Panel@DynamicModule[{input = ""}, 
     InputField[Dynamic[input], String]], "Output",  
   CellEditDuplicate -> False, Deployed -> True];

Actually, with CellEditDuplicate->False should be enough. However, keep Deployed in mind if you use other styles, and so Evaluatable->False

score 2 · Answer 4 · answered Nov 28 '17 at 07:19

2

There appears to be an undocumented InputBoxOptions "TrapEnterKey" which does just that:

InputField[
  Dynamic[x]
, String
, BaseStyle -> InputFieldBoxOptions -> {"TrapEnterKey" -> True}
]

answered Nov 28 '17 at 07:19

Kuba

136,707
13
279
740

In InputField, how to prevent Shift-Return from generating a new cell?

4 Answers4

Linked

Related