Exclude data from a list

Question

Let's create some random sample data

data = Table[{RandomReal[{-10, 10}], RandomReal[{-10, 10}]}, {i, 1, 300}];

Then we plot them using ListPlot

L0 = ListPlot[data, Frame -> True, Axes -> False, AspectRatio -> 1]

And here is the output

Now, how can I select from the screen plot some date (those inside the red closed regions) using the mouse and then delete them form the list, thus creating a new list (data1)? Note here, that we don't know the equations of the red closed regions; they are completely arbitrary.

Any ideas?

Answer 1

data = Table[{RandomReal[{-10, 10}], RandomReal[{-10, 10}]}, {i, 1, 300}]; 
L0 = ListPlot[data, Frame -> True, Axes -> False, AspectRatio -> 1, 
  ImageSize -> 400, BaseStyle -> PointSize[.02]];

Using @rm-rf's function inPolyQ

inPolyQ[poly_, pt_] := Graphics`Mesh`PointWindingNumber[poly, pt] =!= 0

from this Q/A:

Deploy@ DynamicModule[{list = {}}, 
   Row[{EventHandler[Dynamic[Show[L0, Graphics[{Opacity[.7], Yellow, EdgeForm[Thick], 
                      Polygon[list], Purple, PointSize[.03], Point[list]}, 
                      PlotRange -> PlotRange[L0]]]],
          {"MouseDragged" :>  AppendTo[list, MousePosition["Graphics"]]}], 
       Dynamic@ListPlot[If[Length@list <= 2, data, 
                      Style[#, If[inPolyQ[list, #], Red, Blue]] & /@ data], 
                      BaseStyle -> PointSize[.02], Axes -> False, L0[[2]], 
               Prolog -> {Opacity[.5], Yellow, Polygon[list]}]}, Spacer[5]]]

Change the first argument of ListPlot to

If[Length@list <= 2, data, Pick[data, ! inPolyQ[list, #] & /@ data]]

to delete the points inside the selected polygon:

Note: As is, this can handle a single polygon. With some additional effort, it should be possible to handle multiple separate polygons.

Answer 2

Here's a very simple example of a circular "eraser" which you can move around with the mouse and adjust the radius with a slider. Then click the button to remove points within the circle from data.

DynamicModule[{pt = {0, 0}, r = 3}, Column[{
   Slider[Dynamic[r], {0.1, 5}],
   Button["Delete", data = Select[data, EuclideanDistance[#, pt] > r &]],
   LocatorPane[Dynamic[pt],
    Dynamic[ListPlot[data, Frame -> True, Axes -> False, AspectRatio -> 1, 
      Epilog -> Circle[pt, r], ImageSize -> 300]], 
    Appearance -> None]}]]

Answer 3

I know it doesn't really answers the question (since it doesn't use a region or anything else) but you could do the following (which is based on that) to delete the points you wish to delete:

DynamicModule[{range = {-10, 10}, defpts = 100, pts, ptList = None, 
  ptCoord, selectedpt, ptPos, reset, create, selectpt, deselectpt, 
  deletept, firstPosition, export},
 firstPosition[list_, case_] := Position[list, case, 1, 1][[1, 1]];
 Panel@Column@{Button["Export Current data", export[], ImageSize -> 400],
    Panel[Graphics[{Dynamic[({EventHandler[{Dynamic[{If[selectedpt === #, 
                 deletept@selectedpt], Point[# /. ptCoord]}, 
               TrackedSymbols :> {selectedpt, ptCoord}]}, 
             {{"MouseDown", 1} :> (selectedpt = #;),
              {"MouseUp", 1} :> (selectedpt = deselectpt[];)}]} & /@ 
          ptList), TrackedSymbols :> {ptList}]}
      , PlotRange -> {range, range}, Frame -> True, 
      Background -> White], ImageSize -> 400, Background -> White]},
 Initialization :> (
   export[] := Export["~/test.dat", Last /@ ptCoord];
   selectpt[pt_] := (selectedpt = pt; ptPos = firstPosition[First /@ ptCoord, pt]);
   deselectpt[] := (selectedpt = ptPos = {});
   deletept[n_] := If[pts > 0, pts = pts - 1;
     ptList = DeleteCases[ptList, n];
     ptCoord = DeleteCases[ptCoord, _[n, _]];];
   reset[] := (selectedpt = {}; create@defpts;);
   create[n_] := (pts = n; ptList = Range@pts;
     ptCoord = Thread[ptList -> RandomReal[range, {defpts, 2}]];);
   reset[];)]

By clicking on "Export Current data" you would have in my case:

Import["~/test.dat"] // Length

87

It is unfortunately quite slow with bigger list, if anyone knows how to speed it up please let me know :)

Answer 4

Try the function deletePoints[lst,imageSize] given below. Its first argument is the list of points, some of which you wish to delete, the second is the size of the image that you see on the screen for the convenience of working. The function shows the list on a LocatorPane, and you can select the points by Alt+LeftMouseClick, which brings up a locator in the vicinity of the point in question. You do not need to exactly hit the point in question. It is enough to place the locator closer to this point, than to the other ones. As soon as the points are selected, press the button in the bottom of the image. This generates two global variables: lstDeleted and lstSurvived. By evaluating them you get the both lists, and may then plot them, or do whatever else.

The function:

 deletePoints[lst_List, imageSize_Integer] := 
  DynamicModule[{pts = {}, lstNearest},
   lstNearest[a_List, b_List] := (Nearest[a, #, 1] // First) & /@ b;
   Column[{
     Dynamic@LocatorPane[
       Dynamic[pts],
       Dynamic@ListPlot[lst, ImageSize -> imageSize],
       LocatorAutoCreate -> True, ImageSize -> imageSize
       ],
     Button["Make the lists of survived and deleted points",
      Clear[lstDeleted, lstSurvived]; 
      lstDeleted = lstNearest[lst, pts];
      lstSurvived = 
       Delete[lst, First /@ (Position[lst, #] & /@ lstDeleted)]
      ]
     }]];

Example of its functioning. Let this be a list in question:

    lst = RandomReal[{-10, 5}, {10, 2}]

  (*  {{4.20383, -2.58995}, {-0.928284, -4.00225}, {1.61195, -9.17291},{-1.58935, 
      0.338292}, {-0.719281, -7.70116}, {-1.93687, -1.35842}, {-3.26784,-2.04274}, {-8.16471, -4.36758}, {-0.585342, -6.41022}, {-7.04512, 1.20394}}  *)

Apply the function:

deletePoints[lst, 400]

and select few points. I selected three that you can see in the image below. Press the button and evaluate the variables:

    lstSurvived
lstDeleted

(*  {{4.20383, -2.58995}, {1.61195, -9.17291}, {-1.58935, 
  0.338292}, {-0.719281, -7.70116}, {-3.26784, -2.04274}, {-0.585342,-6.41022}, {-7.04512, 1.20394}}

{{-0.928284, -4.00225}, {-1.93687, -1.35842}, {-8.16471, -4.36758}}  *)

Have fun!