Select a particular rules out of a list

Question

rule = {beta -> 4, alpha -> 2, x -> 4, z -> 2, w -> 0.8}
Select[rule, beta]
Select[rule, beta &]
Select[rule, beta -> _ &]

How would I select the rule that applies to beta only?

Or more general, how to select the rules apply to alpha and beta (or more variable, but not all of them)?

Thanks.

kglr · Accepted Answer · 2014-12-18T17:42:03.790

18

You can also use FilterRules:

rule = {beta -> 4, alpha -> 2, x -> 4, z -> 2, w -> 0.8};

FilterRules[rule, beta]
(* {beta -> 4} *)

FilterRules[rule, {beta, alpha}]
(* {beta -> 4, alpha -> 2} *)

Update: additional alternatives if you have V10:

KeyTake[rule,{alpha, x}]
(* or *) KeyTake[{alpha,x}][rule]
(* <|alpha->2,x->4|> *)
Normal@KeyTake[rule,{alpha, x}]
(*  {alpha->2,x->4} *)

KeySelect[rule, MatchQ[#,alpha|x]&]
(* or *) KeySelect[MatchQ[#,alpha|x]&][rule] 
(* <|alpha->2,x->4|>  *)
Normal@KeySelect[rule, MatchQ[#,alpha|x]&]
(*  {alpha->2,x->4} *)

edited Dec 18 '14 at 17:42

answered Dec 18 '14 at 16:20

kglr

394,356
18
477
896

1

Yeah, I certainly need more sleep... – Kuba Dec 18 '14 at 16:23
@Kuba Why? Your method is perfectly adequate. – Mr.Wizard Dec 18 '14 at 17:05
Nice use of KeyTake. That one isn't in my repertoire yet. – Mr.Wizard Dec 18 '14 at 17:43
@Mr.Wizard, thank you. Added to my repertoire a minute ago:) – kglr Dec 18 '14 at 17:44
Warning: KeyTake will by nature return only one rule for each key: KeyTake[{a -> b, b -> c, c -> d, b -> 2}, b] yields <|b -> 2|>. – Mr.Wizard Dec 18 '14 at 17:47
1

@Mr.Wizard, do we need a similar warning for KeySelect? (I am getting the message "You have exceeded the session memory limit for your plan" when i try to run KeySelect[MatchQ[#,b]&][{a -> b, b -> c, b -> 2}] on the free wolfram programming cloud). – kglr Dec 18 '14 at 17:56
@kguler that appears to hang in a Notebook as well. – Mr.Wizard Dec 18 '14 at 18:23
@kglr, how to pick composite key patterns, eg given {{a, x} -> 1, {b, y} -> 2} how to pick {a,x}? Whether as is or wrapped in Key[{a,x}], neither KeyTake or FilterRules matches. – alancalvitti Mar 29 '17 at 18:15
@alancalvitti, FilterRules[{{a, x} -> 1, {b, y} -> 2}, HoldPattern@{a, x}] works in versions 9 and later and KeyTake[{{a, x} -> 1, {b, y} -> 2}, {{a, x}}] works in version 11. – kglr Mar 29 '17 at 20:27

score 7 · Answer 2 · answered Dec 18 '14 at 16:25

7

Select[rule, MemberQ[{beta, alpha}, #[[1]]] &]

answered Dec 18 '14 at 16:25

Basheer Algohi

19,917
1
31
78

score 6 · Answer 3 · answered Dec 18 '14 at 15:31

6

V9 style

If rule is a simple list of rules:

Cases[rule, _[beta | alpha, _]]

{beta -> 4, alpha -> 2}

other ways to go:

{beta, alpha} /. (# -> Rule[##] & @@@ rule)

answered Dec 18 '14 at 15:31

Kuba

136,707
13
279
740

First approach is simple to understand. second approach looks more complicated though. – Chen Stats Yu Dec 18 '14 at 15:52
1

@ChenStatsYu Take a look at (# -> Rule[##] & @@@ rule) – Kuba Dec 18 '14 at 15:54
@kuba I am trying to replicate your first solution as follows: Cases[rule, Rule[beta | alpha, _]] but it did not work. do you know why? this works fine Cases[{{a, 3}, {b, 4}, {c, 5}}, List[a | b, _]] – Basheer Algohi Dec 18 '14 at 16:36
@Algohi Rule makes Cases think that you want to replace beta|alpha with _. Since by default Cases works on level {1} it can't find anything anyway. To make use of explicitly stated Rule you need HoldPattern[...] – Kuba Dec 18 '14 at 16:42

score 5 · Answer 4 · answered Dec 18 '14 at 17:11

5

One more method using Pick and Keys:

Pick[rule, Keys@rule, alpha | beta]

{beta -> 4, alpha -> 2}

answered Dec 18 '14 at 17:11

Mr.Wizard

271,378
34
587
1,371

SquareOne · Answer 5 · 2014-12-18T21:19:28.557

5

Rule[#, (Association@rule)[#]] & /@ {beta, alpha}

{beta -> 4, alpha -> 2}

edited Dec 18 '14 at 21:19

answered Dec 18 '14 at 18:31

SquareOne

7,575
1
15
34

Select a particular rules out of a list

5 Answers5

Linked