I want to calculate the equation in terms of the lambda

Question

(2/5)^(2/5) Sqrt[x] λ^(1/5)
   BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/
   5] + ((-2)^(2/5) Sqrt[x] λ^(1/5)
   BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5])/5^(2/5)==0

Answer 1

We can solve the equation after a fashion with some algebraic manipulation. There infinitely many complex solutions, but Mathematica can find the ones in a finite domain.

Here is the left hand side of the OP's equation:

lhs = (2/5)^(2/5) Sqrt[x] λ^(1/5) BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/5] + 
     ((-2)^(2/5) Sqrt[x] λ^(1/5) BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5])/5^(2/5);

Look at the factors and solve each equal to zero. There is one factor that is left unsolved, saved in the variable eqs. Its left hand side is a function of u = 4/5 x^(5/4) Sqrt[λ]; the replacement rule λ2u = 4/5 x^(5/4) Sqrt[λ] -> u will put it in terms of u.

List @@ Factor@lhs
(*
  {(2/5)^(2/5),
   Sqrt[x],
   λ^(1/5), 
   BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/5] +
     (-1)^(2/5) BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5]}
*)

λ2u = 4/5 x^(5/4) Sqrt[λ] -> u;
sol0 = Solve[# == 0, λ] & /@ List @@ Factor@lhs;
{sols, eqs} = GatherBy[Join[{{}}, sol0], FreeQ[#, Solve] &];
sols
eqs = First /@ eqs
eqs /. λ2u

Solve::nsmet: This system cannot be solved with the methods available to Solve. >>

(*
  {{}, {}, {{}}, {{λ -> 0}}}
  {BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/5] +
    (-1)^(2/5) BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5] == 0}
  {BesselI[-(2/5), u] C[1] Gamma[3/5] + (-1)^(2/5) BesselI[2/5, u] C[2] Gamma[7/5] == 0}
*)

Update: As DumpsterDoofus pointed out, λ -> 0 is only a solution when C[1] == 0; otherwise, the left hand side is undefined.

Given numeric values for C[1] and C[2], Mathematica can solve the remaining equation in a limited domain. The function u0 solves for u, given valus c1, c2 for C[1], C[2] resp., and a finite domain in which to search for roots. I somewhat arbitrarily set up the default domain to be -10 <= Re[u] <= 10 && -10 <= Im[u] <= 10 (because ±1 yields no roots). The results of an exact solution are returned in terms of Root objects (see, for example, How do I work with Root objects?).

u0[c1_?NumericQ, c2_?NumericQ, 
   domain : {z1_?NumericQ, z2_?NumericQ} : {-10 - 10 I, 10 + 10 I}] := 
  Quiet[
   Solve[
    (First@eqs /. λ2u /. {C[1] -> c1, C[2] -> c2}) && 
     Re[z1] <= Re[u] <= Re[z2] && Im[z1] <= Im[u] <= Im[z2],
    u],
   Solve::ratnz];

Now we can use the solutions for u given by u0 to solve for λ by reversing the substitution.

First@Solve[#, λ] & /@ Thread[(u /. Reverse[λ2u]) == u /. u0[1, 1]]

Solve::incs: Warning: Solve was unable to prove that the solution set found is complete. >>

(*
  {{λ -> (1/(16 x^(5/2)))25 Root[{
     BesselI[-(2/5), #1] Gamma[3/5] + (-1)^(2/5) BesselI[2/5, #1] Gamma[7/5] &,
     -0.3705505531326194245117619840662337995953846760177051847 + 
      7.4965854610603720569205193398193535444066971045089011861 I}]^2},
   {λ -> (1/(16 x^(5/2)))25 (Root[<..>]^2)},
   {λ -> (1/(16 x^(5/2)))25 (Root[<..>]^2)},
   {λ -> (1/(16 x^(5/2)))25 (Root[<..>]^2)},
   {λ -> (1/(16 x^(5/2)))25 (Root[<..>]^2)}}
*)

This gave 5 solutions, in the form λ -> C[3] / x^(5/2), one for each root returned by u0[1, 1].

Interestingly, DSolve can obtain the same form (plus another unsolved equation):

λ2λx = λ -> λ[x];
dsols = DSolve[D[eqs /. λ2λx, x], λ, x]

(*
 {
   {λ -> Function[{x}, C[3]/x^(5/2)]}, 
   Solve[BesselI[-(7/5), 4/5 x^(5/4) Sqrt[λ[x]]] C[1] Gamma[3/5] +
     BesselI[3/5, 4/5 x^(5/4) Sqrt[λ[x]]] C[1] Gamma[3/5] +
     (-1)^(2/5) BesselI[-(3/5), 4/5 x^(5/4) Sqrt[λ[x]]] C[2] Gamma[7/5] +
     (-1)^(2/5) BesselI[7/5, 4/5 x^(5/4) Sqrt[λ[x]]] C[2] Gamma[7/5] == 0,
    λ[x]]}
*)

Answer 2

This does not appear to be possible to solve in Mathematica, but here's a couple steps that might help. Simplify it:

Simplify[(2/5)^(2/5) Sqrt[x] λ^(1/5)
    BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/5] + 
    ((-2)^(2/5) Sqrt[x] λ^(1/5) BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5])/5^(2/5)]

which gives

Sqrt[x] λ^(
 1/5) (BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] C[1] Gamma[3/5] + (-1)^(2/5)
     BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5])

The first case to consider is $x=0$ or $\lambda=0$. Evaluating the limits

Limit[Sqrt[x] λ^(
  1/5) (BesselI[-(2/5), 4/5 x^(5/4) Sqrt[λ]] Gamma[3/5] C[1] + (-1)^(2/5)
      BesselI[2/5, 4/5 x^(5/4) Sqrt[λ]] C[2] Gamma[7/5]), λ -> 0]
Limit[%, x -> 0]

gives

((5/2)^(2/5) Sqrt[x] C[1])/(x^(5/4))^(2/5)
(5/2)^(2/5) C[1]

and the same result is obtained when approaching the origin from other angles. So if C[1] is 0, then $x=0$ or $\lambda=0$ (or both) is a zero. Otherwise, neither is.

Otherwise, if $x\neq0,\lambda\neq0$ then we can remove the factor of $\lambda^{1/5} \sqrt{x}$ and absorb the Gamma constants into C[1] and C[2] to give $$c_1 I_{-2/5}\left(u\right)+c_2 I_{2/5}\left(u\right)=0$$ where $u=\frac{4}{5} x^{5/4} \sqrt{\lambda }$, at which point it would probably be best to consult the DLMF, or somebody at MathematicsSE who knows more about special functions than I do.