How can I format 256 items into a column of four grids of 16 rows and 8 columns?

Question

ab = DisplayForm[
  GridBox[Flatten /@ 
    Transpose@
     Partition[
      Table[{n, 
        FactorInteger[n] /. List[p_Integer, 0] :> HoldForm[p] /. 
           List[p_Integer, k_Integer] :> HoldForm[p^k] /. 
          List[x__] :> Times@x /. {} -> 1}, {n, 1, 256}], 16], 
   GridFrame -> True, RowLines -> True, ColumnLines -> True]]

result image enter image description here

result that I hope enter image description here

How to I divide 256 by pieces of four of horizontal 4 * vertical 16?

http://mathworld.wolfram.com/notebooks/PrimeNumbers/PrimeFactorization.nb — jlptrbsa, Jan 18 '15 at 23:09
You edited your desired result to look different than it did. You want to print a series of "tables" down the page? — Mr.Wizard, Jan 18 '15 at 23:32
Okay. People on this site answer questions voluntarily on their own time, therefore you should be patient. I shall revise my answer when I get around to it. — Mr.Wizard, Jan 19 '15 at 00:29

score 4 · Accepted Answer · edited Apr 13 '17 at 12:55

New answer

Here is a modularized method. The first function is from Trying to write out the prime factorization of a number with CenterDot and Superscript, slightly modified.

Format[primeFactorForm[n_Integer]] := 
  Times @@ Superscript @@@ FactorInteger[n] /. _[x_] :> x

block[n_Integer] :=
  Join @@@ Array[{#, primeFactorForm@#} &[# + 16*#2] &, {16, 4}, {64 n - 63, 0}]

grid[m_?MatrixQ] := 
  With[{th = AbsoluteThickness[3]}, Grid[m, Dividers -> ({#, #} &@{th, {True}, th})]]

Array[grid @ block @ # &, 4] // Column

enter image description here

Old answer for original example

There is probably a cleaner way to write this but here's a start for you:

tab = Table[{n, 
    FactorInteger[n] /. List[p_Integer, 0] :> HoldForm[p] /. 
       List[p_Integer, k_Integer] :> HoldForm[p^k] /. List[x__] :> Times@x /. {} -> 
      1}, {n, 1, 256}];

eight   = Prepend[Table[True, {7}], AbsoluteThickness[3]];

sixteen = Prepend[Table[True, {15}], AbsoluteThickness[3]];

Grid[Flatten /@ Transpose@Partition[tab, 16], Dividers -> {{eight}, {sixteen}}, 
 ItemSize -> Full]

This looks really fun! – Chen Stats Yu Jan 19 '15 at 00:57 — Chen Stats Yu, Jan 19 '15 at 00:57

How can I format 256 items into a column of four grids of 16 rows and 8 columns?

1 Answers1

New answer

Old answer for original example