accessing elements of nested list

Question

I have a list of the form:

toy = {{a, {b, c}}, {d, {e, f}}, {g, {h, j}}, {k, {m, n}}};

and would like to create the list

{{a, c}, {d, f}, {g, j}, {k, n}}

from toy.

The following code does it but I find this esthetically unsatisfactory because I don't like creating the two independent lists toy[[;; , 1]] and toy[[;; , 2, 2]] and combining them.

Transpose[{toy[[;; , 1]], toy[[;; , 2, 2]]}]

Is there a cleaner more direct way to do this?

For ex.{#[[1]], #[[2, 2]]} & /@ toy or {#1, #2[[2]]} & @@@ toy — Dr. belisarius, Jan 27 '15 at 04:49
Just for something different: toy[[All, 2]] = toy[[All, 2, 2]]; toy — Mike Honeychurch, Jan 27 '15 at 04:56
Without destroying the toy Transpose@{toy[[All,1]],toy[[All,2,2]]} — tchronis, Jan 27 '15 at 07:21
@tchronis That method is already in the question as "unsatisfactory" — Mr.Wizard, Jan 27 '15 at 07:25
Incidentally I think something very close to this has been asked before, if not this exact transformation. — Mr.Wizard, Jan 27 '15 at 07:31
@Mr.Wizard, this is close: http://mathematica.stackexchange.com/questions/63989/extracting-columns-from-multidimensional-list — Simon Woods, Jan 27 '15 at 09:13

score 7 · Accepted Answer · answered Jan 27 '15 at 07:08

7

Is this what you want:

Map[{#[[1]], #[[2, 2]]} &, toy]

answered Jan 27 '15 at 07:08

David Schilling

178
6

Kuba · Answer 2 · 2015-01-27T08:02:31.510

4

One should ban all those comments spammers one day... :)

To not duplicate them:

toy[[All , 2, 0]] = #2 &;
toy

{{a, c}, {d, f}, {g, j}, {k, n}}

Keep in mind that this modifies toy.

edited Jan 27 '15 at 08:02

answered Jan 27 '15 at 07:21

Kuba

136,707
13
279
740

+1 nice one :) How come you (and others) use ;; instead of All? – Mike Honeychurch Jan 27 '15 at 07:24
@MikeHoneychurch you mean why? 2 is less than 3 characters :) But may be obscuring sometimes and doesn't work for <V9 in every form. Still, I like it :) – Kuba Jan 27 '15 at 07:27
@Mike Probably to save a character, but even as a terse fanatic I prefer All. First because it is descriptive and ledible, and second because it is backward-compatible. (;; does not work in v7.) It's only one more character so I vote for All. I've even edited it into a few answers here and there. – Mr.Wizard Jan 27 '15 at 07:27
@Mr.Wizard ok ok... :) – Kuba Jan 27 '15 at 07:27
@Kuba Of course you have your own style and it doesn't have to agree with mine. :-) – Mr.Wizard Jan 27 '15 at 07:28
1

@Mr.Wizard I don't! My notebooks are full of ;; :) – Kuba Jan 27 '15 at 07:29

score 4 · Answer 3 · answered Jan 27 '15 at 09:15

4

Maybe:

Extract[{{1}, {2, 2}}] /@ toy

answered Jan 27 '15 at 09:15

Simon Woods

84,945
8
175
324

score 3 · Answer 4 · answered Jan 20 '18 at 00:20

3

☺ = {#, #2 & @@ #2} & @@@ # &;
☺ @ toy

{{a, c}, {d, f}, {g, j}, {k, n}}

answered Jan 20 '18 at 00:20

kglr

394,356
18
477
896

1

Or, {#, Last@#2} & @@@ toy – bbgodfrey Jan 20 '18 at 01:02
2

@bbgodfrey, yes but then we can't say "look ma, no letters!" – kglr Jan 20 '18 at 02:33

score 3 · Answer 5 · answered Jan 27 '15 at 09:10

3

(Flatten /@ toy)[[;; , {1, 3}]]

answered Jan 27 '15 at 09:10

Basheer Algohi

19,917
1
31
78

score 2 · Answer 6 · answered Dec 25 '23 at 00:20

2

list = {{a, {b, c}}, {d, {e, f}}, {g, {h, j}}, {k, {m, n}}};

Using ReplaceAt (new in 13.1)

ReplaceAt[list, {_, a_} :> a, {;; , 2}]

{{a, c}, {d, f}, {g, j}, {k, n}}

answered Dec 25 '23 at 00:20

eldo

67,911
5
60
168

E. Chan-López · Answer 7 · 2023-12-25T02:46:53.360

1

Using ReplaceList:

list = {{a, {b, c}}, {d, {e, f}}, {g, {h, j}}, {k, {m, n}}};
ReplaceList[#, {s1_, {s2__}} :> Splice@{s1, First@s2}] & /@ list
({{a, c}, {d, f}, {g, j}, {k, n}})

Or using Cases:

Cases[#, {s1_, {s2__}} :> {s1, First@s2}] &@list
({{a, c}, {d, f}, {g, j}, {k, n}})

Or using ReplaceAll:

# /. {s2_, s3 : {__}} :> {s2, Last@s3} &@list
({{a, c}, {d, f}, {g, j}, {k, n}})

edited Dec 25 '23 at 02:46

answered Dec 25 '23 at 01:45

E. Chan-López

23,117
3
21
44

score 1 · Answer 8 · answered Dec 25 '23 at 02:29

toy = {{a, {b, c}}, {d, {e, f}}, {g, {h, j}}, {k, {m, n}}};

Cases[toy, {a_, {b_, c_}} :> {a, c}]
{First@#, Last@Last@#} & /@ toy
Flatten@*ReplacePart[{{2, 1}} -> Nothing] /@ toy
Flatten@*Delete[{2, 1}] /@ toy
#[[{1, -1}]] &@*MapAt[Splice, 2] /@ toy
{First@#, Last@#} & /@ MapAt[Splice, toy, {All, 2}]
Through[{First, Last}[#]] & /@ MapAt[Splice, toy, {All, 2}]

Result:

{{a, c}, {d, f}, {g, j}, {k, n}}

accessing elements of nested list

8 Answers8