Nested mapping of a function

Question

If I use the construct

f[#] & /@ f[#] & /@ f[#] & /@ {a, b, c}

my function works, but if I use

Nest[f, #, 3] & /@ {a, b, c}

it doesn't. What is the difference, and how can I code the top example without copying and pasting?

Both give the same result in Version 9.0.1.0 (Windows 8 x64). — kglr, Feb 11 '15 at 03:27
Have you tried both versions on a fresh (new) Mathematica session? — Dr. belisarius, Feb 11 '15 at 03:33
They are not the same if you define something for f. Try it with, say, f = #+1&. — wxffles, Feb 11 '15 at 03:37
as wxffles says, there is a slight difference in nesting. It can be simulated by adding parentheses. — martin, Feb 11 '15 at 03:43
Are you certain that you want a neat version of the first construct? Honest question — Rojo, Feb 11 '15 at 06:38
@Rojo I say yes with trepedation ... I am guessing it is rather complicated ... — martin, Feb 11 '15 at 10:08

score 5 · Accepted Answer · edited Apr 13 '17 at 12:56

Analysis

Function is left-associative as converting to StandardForm reveals:

(((f[#1] &) /@ f[#1] &) /@ f[#1] &) /@ {a, b, c}

You can see the result of the rather odd operation with:

f = {#, "x"} &;

f[#] & /@ f[#] & /@ f[#] & /@ {a, b, c}

{{{{a, x}, {x, x}}, {{x, x}, {x, x}}},
 {{{b, x}, {x, x}}, {{x, x}, {x, x}}},
 {{{c, x}, {x, x}}, {{x, x}, {x, x}}}}

(Obviously the structure is specific to the output of f but I hope it serves to illustrate.)

Additionally the order of evaluation is not the same as a Map operation with a levelspec because one entire branch executes first. Compare these results:

i = 0;
f = {#, i++} &;
f[#] & /@ f[#] & /@ f[#] & /@ {a, b, c}

{{{{a, 2}, {1, 3}}, {{0, 5}, {4, 6}}},
 {{{b, 9}, {8, 10}}, {{7, 12}, {11, 13}}},
 {{{c, 16}, {15, 17}}, {{14, 19}, {18, 20}}}}

i = 0;
f = {#, i++} &;
Fold[Map[f, #, {#2}] &, {a, b, c}, Range@3]

{{{{a, 9}, {3, 10}}, {{0, 11}, {4, 12}}},
 {{{b, 13}, {5, 14}}, {{1, 15}, {6, 16}}},
 {{{c, 17}, {7, 18}}, {{2, 19}, {8, 20}}}}

I am attempting to think of a clean way to produce the first output (with arbitrary levels of mapping).

Solution

After a chat session I propose:

mapRepeated[f_, expr_, n_Integer?Positive] :=
  Nest[x \[Function] x /@ f[#] &, f, n - 1] /@ expr

Test:

i = 0;

mapRepeated[{#, i++} &, {a, b, c}, 3]

{{{{a, 2}, {1, 3}}, {{0, 5}, {4, 6}}},
 {{{b, 9}, {8, 10}}, {{7, 12}, {11, 13}}},
 {{{c, 16}, {15, 17}}, {{14, 19}, {18, 20}}}}

Using Mathematica 10 syntax the we can simplify mapRepeated slightly:

mapRepeated[f_, expr_, n_Integer?Positive] :=
  Nest[Map[#]@*f &, f, n - 1] /@ expr

Your are faster ;) so you can add that this fact may be surprising because: f /@ f /@ f /@ {a} works differently. — Kuba, Feb 11 '15 at 10:38
@martin If your first way is ok but second gives wrong result I'd think that the problem is in f. The question is, do you want to repeatively map f over a set? Well, you are not doing this with your first solution. (but maybe I've missed something) — Kuba, Feb 11 '15 at 10:44
@Mr.Wizard Ah, just found out that the order is important - sorry! :( — martin, Feb 11 '15 at 11:18

Basheer Algohi · Answer 2 · 2015-02-11T11:21:28.627

0

I am not sure which from of the solutions you are looking at but you can try this:

f = #+1&; 
Composition[Sequence @@ ConstantArray[f, 2]][f[#]] & /@ {a, b, c}
(*{3 + a, 3 + b, 3 + c}*)

how about this:

Nest[Map[f, #,{-1}] &, f[#], 2] & /@ {a, b, c}

edited Feb 11 '15 at 11:21

answered Feb 11 '15 at 10:16

Basheer Algohi

19,917
1
31
78

Not working with my function I'm afraid - sorry to be a pain! – martin Feb 11 '15 at 10:22
Not working at all or gives different result than you expected? – Basheer Algohi Feb 11 '15 at 10:23
I think it must be my strangely constructed initial function. – martin Feb 11 '15 at 10:24
It works well on the example you gave, but my function doesn't like it. – martin Feb 11 '15 at 10:24
@Algori I'm afraid not - the first gies the same output as Nest[f, #, 3] & /@ {a, b, c}, the second gives a different output, but not the desired one. – martin Feb 11 '15 at 10:32
I get confused. which results you are looking for in your question. is it the result from f[#] & /@ f[#] & /@ f[#] & /@ {a, b, c} or from Nest[f, #, 3] & /@ {a, b, c}? – Basheer Algohi Feb 11 '15 at 10:34
unfortunately, that doesn't work wither. BTW it is the first of your 2 examples that I am after - f[#] & /@ f[#] & /@ f[#] & /@ {a, b, c} – martin Feb 11 '15 at 11:34
Hmmm, I give up :) – Basheer Algohi Feb 11 '15 at 11:44

Nested mapping of a function

2 Answers2

Analysis

Solution

Linked

Related