Duplicate mapped elements in Riffle

Question

What is the best way to do this?

in:

{a, b, c}
{d, {e, f}, g}

out:

{{a, d}, {b, e}, {b, f}, {c, g}}

If[Length[#[[2]]] > 0, Transpose[{Table[#[[1]], {x, Length[#[[2]]]}], #[[2]]}], #] 
& /@ Partition[Riffle[{a, b, c}, {d, {e, f}, g}], 2]

seems a bit longwinded.

Just for fun, not good for numbers :) : Flatten[MapThread[ArcTan, {{a, b, c}, {d, {e, f}, g}}]] /. ArcTan -> List. — Kuba, Feb 20 '15 at 19:27
@Kuba You jogged a memory. I think this question is a duplicate. I remember writing this before: Quiet@Re[{a, b, c}, {d, {e, f}, g}] /. Re -> List. Let me see if I can find it. — Mr.Wizard, Feb 20 '15 at 19:32
Related: (17400), and my answer with Re: (28693). Sadly no votes. :'-( — Mr.Wizard, Feb 20 '15 at 19:34
This question is almost a duplicate of 17400 linked above, but flat output is desired. I don't know if that is enough to keep this open or not. I'll let the community votes decide. — Mr.Wizard, Feb 20 '15 at 19:35

kglr · Accepted Answer · 2017-10-25T10:16:04.897

10

l1 = {a, b, c};
l2 = {d, {e, f}, g};

Partition[Flatten[Thread /@ Thread[{l1, l2}]], 2]

{{a, d}, {b, e}, {b, f}, {c, g}}

or

(## & @@ Thread @ #) & /@ Thread[{l1, l2}]

{{a, d}, {b, e}, {b, f}, {c, g}}

edited Oct 25 '17 at 10:16

answered Feb 20 '15 at 18:55

kglr

394,356
18
477
896

very nice .....:) – martin Feb 20 '15 at 19:02

score 8 · Answer 2 · edited Apr 13 '17 at 12:55

8

Using undocumented Function syntax, Listable, and v10 Composition syntax:

fn1 = #[[2, 1]] & @* Reap @* Function[, Sow[{##}], Listable];

fn1[{a, b, c}, {d, {e, f}, g}]

{{a, d}, {b, e}, {b, f}, {c, g}}

This works at deeper levels as well:

fn1[{a, b, c}, {d, {{e1, e2}, f}, g}]

{{a, d}, {b, e1}, {b, e2}, {b, f}, {c, g}}

Another method without the undocumented functionality:

With[{h = Unique["h", Listable]},
  fn2 = Cases[h[##], h[e__] :> {e}, -1] &
]

Test:

fn2[{a, b, c}, {d, {{e1, e2}, f}, g}]

{{a, d}, {b, e1}, {b, e2}, {b, f}, {c, g}}

edited Apr 13 '17 at 12:55

Community

1

answered Feb 20 '15 at 19:22

Mr.Wizard

271,378
34
587
1,371

great :) Its a bit strange though because the double slot is pink in my Mathematica ... it works though! – martin Feb 20 '15 at 19:24
1

@martin Please see the alternative I added. – Mr.Wizard Feb 20 '15 at 19:29
Nice alternative to using SetAttributes there, I'll have to remember that! – Simon Woods Feb 20 '15 at 20:58
@Simon Thank Oleksandr: (15032) – Mr.Wizard Feb 21 '15 at 01:23

score 3 · Answer 3 · answered Oct 21 '23 at 08:21

3

Using ReplaceAll with Splice (since V. 13.1)

l1 = {a, b, c};
l2 = {d, {e, f}, g};
Transpose[{l1, l2}] /. {a_, {b_, c_}} :> Splice[{{a, b}, {a, c}}]

{{a, d}, {b, e}, {b, f}, {c, g}}

answered Oct 21 '23 at 08:21

eldo

67,911
5
60
168

user1066 · Answer 4 · 2023-10-21T10:19:10.540

3

Update

MapThread[Thread@*List,{l1,l2}]//FlattenAt[2]
(* {{a,d},{b,e},{b,f},{c,g}} *)

Or

Level[MapThread[Thread@*List,{l1,l2}],{-2}]
(* {{a,d},{b,e},{b,f},{c,g}} *)

Original Answer

MapThread[Thread[Distribute[{##}]]&,{l1,l2}]//FlattenAt[2]
(* {{a,d},{b,e},{b,f},{c,g}} *)

Or

Level[MapThread[Thread[Distribute[{##}]]&,{l1,l2}],{-2}]
(* {{a,d},{b,e},{b,f},{c,g}} *)

edited Oct 21 '23 at 10:19

answered Oct 21 '23 at 09:28

user1066

17,923
3
31
49

score 3 · Answer 5 · answered Feb 20 '15 at 18:37

3

One way:

ff = Flatten[#, 1] &; 
ff@MapThread[Function[{u, v}, {u, #} & /@ ff[{v}]], {{a, b, c}, {x, {y, u}, z}}]

(* {{a, x}, {b, y}, {b, u}, {c, z}}*)

answered Feb 20 '15 at 18:37

Dr. belisarius

115,881
13
203
453

1

that's a bit more elegant :) – martin Feb 20 '15 at 18:40

score 3 · Answer 6 · answered Feb 21 '15 at 03:03

3

l1 = {a, b, c};
l2 = {d, {e, f}, g};    
Level[Thread[{#, #2}] & @@@ Transpose[{l1, l2}], {-2}]
(*{{a, d}, {b, e}, {b, f}, {c, g}}*)

answered Feb 21 '15 at 03:03

Basheer Algohi

19,917
1
31
78

This does assume that list elements are atomic, but +1. – Mr.Wizard Feb 21 '15 at 07:07

Duplicate mapped elements in Riffle

6 Answers6