How to make text flash for a short period

Question

How could I display text that flashed red for a half second or so and then reverted to black? (Or was put in bold and reverted to normal, etc.)

Answer 1

By specifying different values for time and frequencyInverse, the behavior of flashing can be finetuned.

time = 100;
frequencyInverse = 4;

i = 0;
Dynamic@Style["TESTESTEST", Bold, RGBColor[color, 0, 0]]
RunScheduledTask[(i = i + 1; color = Rescale[Sin[i/frequencyInverse], {-1, 1}]; 
  If[i == time, RemoveScheduledTask[ScheduledTasks[]]; 
   color = 0]), {.01, \[Infinity]}];

(Not that the actual flashing is faster in Mathematica, the slowdown is because of exporting it to GIF.)

With Clock:

time = 1; (* period length *)
iterations = 5; (* number of successive flashes *)
img1 = DensityPlot[Sin[x] Sin[y], {x, -4, 4}, {y, -3, 3}, 
   ImageSize -> 50, Frame -> False];
img2 = DensityPlot[Sin[x] Sin[y], {x, -4, 4}, {y, -3, 3}, 
   ColorFunction -> "SunsetColors", ImageSize -> 50, Frame -> False];
Dynamic@Overlay[{img1, 
   SetAlphaChannel[
    img2, (1 - Abs@Clock[{-1, 1, .1}, time, iterations])]}]

Answer 2

Use Dynamic and Refresh:

Dynamic[Refresh[
  Style["text", 
   FontColor -> If[Mod[Round[AbsoluteTime[]], 2] == 0, Red, Black]], 
  UpdateInterval -> 1]]

Answer 3

 PrintTemporary[Style["text", Red]]; Pause[2]; "text"

EDIT: This looks too plain in comparison to all the cool effects that can be achieved with methods used in other answers. The following is an attempt to arm-twist PrintTemporary to perform similar tricks:

 Scan[(temp = PrintTemporary[#]; Pause[.1]; NotebookDelete[temp]) &, 
   Style[Rotate["text", #[[1]]], Bold, 60, FontColor -> #[[2]], 
    FontFamily -> "SketchFlow Print"] & /@ 
   NestList[{Plus[#[[1]], 20 Degree], Darker[#[[2]]]} &, {0 Degree,Red}, 18]]; "text"

(Note: try it in the last cell of your notebook to avoid flickering cell sizes).

Answer 4

Style["TESTESTEST", FontColor -> Dynamic[If[Clock[] 2 - 1. > 0, Red, Black]]]

If you want it to flash only once

Style["TESTESTEST", FontColor -> Dynamic[If[Clock[{-1, 1, 1}, 1, 1] > 0, Black, Red]]]

Answer 5

As a variation of answer to this question, here is an approach I used for lectures. Here are the functions Ac and Pl that either accentuate or leave the text plain:

Ac[expr_] :=
  DynamicModule[{c1 = 0}, EventHandler[
    Dynamic[
     If[c1 == 0,
      Style[expr, Black, Plain, 22, Italic] // ExpressionCell, 
      Dynamic @ If[Clock[1, 0.7, 2] < .5, 
         Style[expr, Gray, Plain, 22, Italic] // ExpressionCell, 
         Style[expr, RGBColor[0.8, 0, 0], Bold, 22, Italic]] // ExpressionCell]],
    {"MouseDown" :> (c1 = c1 /. {0 -> 1, 1 -> 0})}
  ]];

and

Pl[expr_] := ExpressionCell[Style[expr, Black, Plain, 22, Italic]];

And here is an example of its application:

F = Row[{"AA" // Pl, "+BB" // Ac, "+CC" // Pl, "+DD" // Ac}]

The strings "+BB" and "+DD" are accentuated. The accentuation is shown upon the mouseclick on the corresponding elements.

Answer 6

It's worth pointing out that several of the other answers keep dynamically re-evaluating an expression until infinity.

Here's a solution that fades out the text gradually, and more importantly: it does not keep re-evaluating the Dynamic expression until infinity. The third argument of Clock (and the fact that Dynamic is smart when handling Clock) can be used to terminate the evaluation.

flash[expr_] := 
 Dynamic[Style[expr, Blend[{Red, Black}, Clock[{0, 1}, 1, 1]]]]

flash["Boo!"]

(Update: I overlooked that István's original answer uses Clock in the same way.)