Function in Table

Question

I need a table with the elements made of pure functions and list elements. This is a simplified example:

I need a list as:

{a[[1]]*Sin[#]&,a[[2]]*Sin[#]&,a[[3]]*Sin[#]&}

and, my failed try is : Table[a[[i]]*Sin[#]&,{i,3}]

Why is the failure and how can I improve it?

What's a supposed to be? Do you need something like the result of Function[c, c Sin[#] &] /@ Range[3] or Table[With[{cs = c}, cs Sin[#] &], {c, Range[3]}]? — J. M.'s missing motivation, Jul 01 '12 at 17:13
@R.M, that puts the constant outside the Function[] as opposed to the inside, no? — J. M.'s missing motivation, Jul 01 '12 at 17:23
Also, I illustrate various techniques of generating lists of pure functions with injected elements (very close to what you ask for), in this answer. — Leonid Shifrin, Jul 01 '12 at 17:27
@LeonidShifrin, you'll make him cry while trying to follow that code! — Rojo, Jul 01 '12 at 17:29
@Rojo But the part on pure functions is in the middle of the post, and independent on anything else - have a look. — Leonid Shifrin, Jul 01 '12 at 17:30
Wow, Rojo and WReach posted at the exact same time, down to the second! — rm -rf, Jul 01 '12 at 17:32
@R.M. Apparently, one second granuarity is not enough (too coarse). — Leonid Shifrin, Jul 01 '12 at 17:34
My favorites for this problem would still be either Range[3] /. i_Integer :> (a[[i]] Sin[#] &) or Array[Function[x, a[[x]] Sin[#] &], {3}]. — Leonid Shifrin, Jul 01 '12 at 17:38
Has anyone mentioned Evaluate?"Table[Evaluate[a[[i]]*Sin[#]]&,{i,3}]" — , Feb 03 '14 at 15:50

WReach · Accepted Answer · 2017-03-22T16:51:22.637

45

Function has the attribute HoldAll, so the reference to i in the Table expression will not be expanded.

However, you can use With to inject the value into the held expressions:

Table[With[{i = i}, a[[i]]*Sin[#] &], {i, 3}]

{a[[1]] Sin[#1] &, a[[2]] Sin[#1] &, a[[3]] Sin[#1] &}

This issue will be present not only for Function but for all expressions that hold their arguments (via attributes like HoldFirst) -- for example: Plot, Dynamic, RuleDelayed (:>) etc.

The solution using With is mentioned in the tutorial "Introduction To Dynamic / A Good Trick to Know".

edited Mar 22 '17 at 16:51

answered Jul 01 '12 at 17:23

WReach

68,832
4
164
269

If I do a = Range[3]; Table[With[{i = i}, a[[i]] Sin[#] &], {i, 3}], then the a[[i]] remain frozen as Part[] expressions as opposed to whatever the actual values of the a[[i]] are, but maybe this is what the OP wants... – J. M.'s missing motivation Jul 01 '12 at 17:33
@J.M. It gets substituted when the function is evaluated: Through[Table[With[{i = i}, a[[i]] Sin[#] &], {i, 3}][x]] – rm -rf Jul 01 '12 at 17:37
@R.M, yes, that's true, but it's still a bit jarring for me to see the list of Function[]s still carrying Part[] objects around... – J. M.'s missing motivation Jul 01 '12 at 17:40
1

@JM, the thing is that the OP showed an example where a is undefined. If you try to evaluate it and it's undefined you get an error – Rojo Jul 01 '12 at 17:44
@Rojo: hence my "what's a supposed to be?" question in my first comment. ;) – J. M.'s missing motivation Jul 01 '12 at 17:51
@J.M. Yes, it's almost like SetDelayed in that changing a changes the functions. Useful to know, but can create unexpected results if one weren't aware of it – rm -rf Jul 01 '12 at 17:55
@Rojo et al: thanks for undelete :) – WReach Jul 01 '12 at 18:32

score 11 · Answer 2 · edited Apr 13 '17 at 12:55

. . . & is a held expression. (Function has attribute HoldAll.)

Injector pattern to the rescue:

Range@3 /. i_Integer :> (a[[i]] Sin[#] &)

Replace[Range@3, i_ :> (a[[i]] Sin[#] &), 1]

Table[j /. i_ :> (a[[i]] Sin[#] &), {j, 3}]

Or using \[Function] and Array:

Array[i \[Function] (a[[i]] Sin[#] &), 3]

In this case you could do the replacement the other direction but you will need to hold i to protect it from a global value:

Table[a[[i]] Sin[#] & /. HoldPattern[i] -> j, {j, 3}]

Or use Block:

Block[{i},
  Table[a[[i]] Sin[#] & /. i -> j, {j, 3}]
]

acl · Answer 3 · 2012-07-01T18:16:23.557

8

This works, but only because j is undefined:

Table[(a[[j]]*Sin[#] &) /. j -> i, {i, 3}]

(if we do j = 5; Table[(a[[j]]*Sin[#] &) /. j -> i, {i, 3}] then it fails; one could localize this with Module to get it to work anyway).

Or, if you hate brevity and compactness:

cF = Function[{j}, a[[j]]*Sin[#] &];
Table[
 cF[j],
 {j, 1, 3}
 ]

Personally I'd use either this last form or WReach's/Rojo's way.

edited Jul 01 '12 at 18:16

answered Jul 01 '12 at 18:07

acl

19,834
3
66
91

@LeonidShifrin thanks. Yes, that it would need to be localized is what I meant (it's accidental that j is undefined). Bad choice of words, I suppose (and, oops, I hadn't seen your comment... why not an answer?) – acl Jul 01 '12 at 18:13
I've already answered a variant of this question twice (in the links I give in the comments to the question). Trying not to be greedy :-) – Leonid Shifrin Jul 01 '12 at 18:15

score 5 · Answer 4 · answered Jan 13 '16 at 15:43

5

With Mathematica 10, you can also do this by

Activate@Table[Inactivate[a[[i]]*Sin[#] &], {i, 3}]

answered Jan 13 '16 at 15:43

matheorem

17,132
8
45
115

Function in Table

4 Answers4

Linked

Related