How can one popup menu be used to add another?

Question

I'm trying to construct a GUI that changes depending on what's chosen in certain popup menu's. For example: The default state of the menu is condition one, but when the first PopupMenu is selected other menu configurations are displayed. To keep the GUI simple each popup menu has a function attached and the menu change allows the user to use a different set of functions. Data input is done by importing so non of these menus provide variable input to functions. I have reviewed this code: Manipulate with a variable number of sliders but have not been able to figure out how to modify it to produce the results I need. Thanks very much for your help! Bad code example follows:

DynamicModule[{n = 1}, 
Column[{Dynamic[
Grid[Table[
  With[{i = i}, {i, 
    PopupMenu[
     Dynamic[data[[i]]], {a -> "one menu" , 
      b -> "Add another Menu" }], Dynamic[data[[i]]]}], {i, 
   n}](*Table*)]](*Dynamic*)}, Center](*Column*)]

I would like the menu to produce a second menu when "Add another Menu" is selected. So for example "Add another menu" is selected and it produces a "New Menu" Popup Menu below it, but remains showing the "Add another menu" selection and does not revert back to "one menu".

@Rojo no prob, In the future I'll try and post a better example. Thanks! — Nothingtoseehere, Jul 03 '12 at 01:55
@Rojo your answer had been deleted but just to follow up -- I am not rejecting the use of tagging rules per se -- I use them often -- just noting that they can be a bottleneck if you have a lot of them and it wasn't clear how big E Halls actual GUI is -- so worth the caveat. — Mike Honeychurch, Jul 03 '12 at 02:01
Mike, I had totally misinterpreted his question, my bad. I thought he wanted a separate dialog in which to choose from certain functions that would be available to him in another separate dialog. Somehow I read popup and thought dialog. So, I thought that if I used dynamic module wormholes, I would still need the generating notebook to link those dialogs... — Rojo, Jul 03 '12 at 02:10
@MikeHoneychurch, forgot to ping you in the previous comment — Rojo, Jul 03 '12 at 03:38

score 11 · Accepted Answer · edited Jul 03 '12 at 11:38

11

Let's see if now I got it better...

DynamicModule[{var = False}, 
Dynamic@Column[{PopupMenu[ 
Dynamic[var], {False -> #, 
True -> "Add another Menu"}],   
If[var, #0["new menu"], ## &[]]}]] &["one menu"]

edited Jul 03 '12 at 11:38

Nothingtoseehere

4,518
2
30
58

answered Jul 03 '12 at 02:23

Rojo

42,601
7
96
188

1

+1 for #0 and ##&[] :-) – Mr.Wizard Jul 03 '12 at 02:28
1

@Mr.Wizard, I already used him once earlier today, which is weird because I never use it, check this. – Rojo Jul 03 '12 at 02:30
@Rojo nicely done! Thanks! – Nothingtoseehere Jul 03 '12 at 02:30
2

One more thing to add to the long list of code samples I need to work through. – Mr.Wizard Jul 03 '12 at 02:30
@Mr.Wizard, the chat thing is not worth it. I just found it interesting that I ended up with a suboptimal solution that was particularly obfuscated and weird. I think I woke up with #0 and patterns in my mind today – Rojo Jul 03 '12 at 02:43
But this one is nice :), I couldn't have done it without you guys ,#0 and ##&[] – Rojo Jul 03 '12 at 02:44
1

@Rojo actually that makes it of interest to me; after all "I code perverse Mathematica" according to Simon. – Mr.Wizard Jul 03 '12 at 02:44
ditto +1 for #0 and ##&[] – Mike Honeychurch Jul 03 '12 at 02:45
@Rojo, How can this code be extended so that when the "Add another menu" pulldown is selected, the new pulldown is visible in the form of "New Menu", and the first pulldown still shows "Add another menu"? Thanks! – Nothingtoseehere Jul 03 '12 at 03:28
@RHall, I didn't understand. What do you want the options of the new pulldown menu to be? – Rojo Jul 03 '12 at 03:35
@Rojo see my edits above Thank you! – Nothingtoseehere Jul 03 '12 at 10:52
So you basically want this same behaviour but, in all but the frist menu, to replace "one menu" by "new menu"? If so, you could pass it as a parameter, like DynamicModule[{var = False}, Dynamic@Column[{PopupMenu[ Dynamic[var], {False -> #, True -> "Add another Menu"}], If[var, #0["new menu"], ## &[]]}]] &["one menu"] – Rojo Jul 03 '12 at 11:05
@RHall, if you confirm I'll edit my answer, or you feel free to edit it for me – Rojo Jul 03 '12 at 11:07
@Rojo, Exactly right thank you! – Nothingtoseehere Jul 03 '12 at 11:17

Mike Honeychurch · Answer 2 · 2012-07-03T01:51:27.267

Some generic examples:

DynamicModule[{var = 3, var2 = 1, var3 = "hello"},

 Column[{
   PopupMenu[
    Dynamic[var], {1 -> "Display Popup", 2 -> "Display Input field", 
     3 -> "None"}],

   PaneSelector[{
     1 -> PopupMenu[Dynamic[var2], Range[4]],
     2 -> InputField[Dynamic[var3]],
     3 -> Spacer[0]
     }, Dynamic[var]]

   }]
 ]

Alternatively use Join and If | Switch | Which to determine what gets displayed:

DynamicModule[{var = 3, var2 = 1, var3 = "hello"},

 Dynamic[
  Column[
   Join[
    {PopupMenu[
      Dynamic[var], {1 -> "Display Popup", 2 -> "Display Input field",
        3 -> "None"}]},

    Switch[var,
     1, {PopupMenu[Dynamic[var2], Range[4]]},
     2, {InputField[Dynamic[var3]]},
     3, {}
     ]
    ]

   ],
  TrackedSymbols :> {var}]
 ]

And you can set other variables based on what gets chosen in your "starting" popup e.g.:

PopupMenu[
 Dynamic[var, (var = #; If[var==1,var2 = 2; var3 = "something"]) &], {1 -> 
   "Display Popup", 2 -> "Display Input field", 3 -> "None"}]

Very cool solution Mike. Works great! Thanks for the help! – Nothingtoseehere Jul 03 '12 at 01:53 — Nothingtoseehere, Jul 03 '12 at 01:53

How can one popup menu be used to add another?

2 Answers2