How can I make a list animation of images that fade in and out?

Question

I'm not sure how to get a "fade in" effect.

@kguler Thanks. I think it's useful, but a different question. — M.R., Jul 05 '12 at 03:30

score 12 · Accepted Answer · answered Jul 04 '12 at 22:07

12

Start from understanding and setting up an transition functions sequence:

Plot[Evaluate@Table[(1 + Tanh[tr (x - dt n)])/2, {n, 1, Length[imgs], 1}], {x, 0, 
  dt (Length[imgs] + 1)}, PlotStyle -> Thick]

enter image description here

Set your images as a list:

enter image description here

Set 2 main parameters of your animation:

tr = 1;(* transition speed *)
dt = 4;(* display time *)

Finally use interactive interface

Animate[Overlay[Table[SetAlphaChannel[imgs[[n]], (1 + Tanh[tr (x - dt n)])/2], {n, 1, 
    Length[imgs], 1}]], {x, 0, dt (Length[imgs] + 1), 
  ImageSize -> Small}, AnimationRate -> 2]

enter image description here

Or make a table and export as an .GIF image

gift = Table[Overlay[Table[SetAlphaChannel[imgs[[n]], (1 + Tanh[tr (x - dt n)])/2], {n,
       1, Length[imgs], 1}]], {x, 0, dt (Length[imgs] + 1), 
    dt (Length[imgs] + 1)/50}];

Export["MyVacationSlideShow.gif", gift]

answered Jul 04 '12 at 22:07

Vitaliy Kaurov

73,078
9
204
355

You don't necessarily have to use the hyperbolic tangent; any number of "sigmoidal" functions ought to do the trick... – J. M.'s missing motivation Jul 05 '12 at 02:22
Lovely answer Vitaliy! See my answer below... – M.R. Jul 05 '12 at 03:30
@J.M.Absolutely, I just like Tanh ;-) – Vitaliy Kaurov Jul 05 '12 at 03:39
@Mike Thanks, your solution is cool too! +1 – Vitaliy Kaurov Jul 05 '12 at 03:40
This is good, but very slow for large Length[imgs]. – user1747134 Mar 17 '18 at 17:50

score 4 · Answer 2 · edited Jul 05 '12 at 06:37

4

Vitaliy has a great answer, however I wanted to try my hand at this to get something a bit smoother in action by using Dynamics...

images = ImageResize[#, 500] & /@ ExampleData /@ ExampleData["TestImage"][[1 ;; 7]];
i = 1;
Dynamic[
    Which[Or @@ Thread[i == Range[Length[images]]], Pause[2]; i += .01, 
      i < Length[images] - 1, i += .01, 
      True, i = 1]; fade = Mod[i, 1];
 ImageCompose[images[[IntegerPart[i]]], {images[[IntegerPart[i] + 1]], fade}]
]

This works, but can someone please tell me why I can't substitute IntegerQ[i] for Or @@ Thread[i == Range[Length[images]]]?

edited Jul 05 '12 at 06:37

Mr.Wizard

271,378
34
587
1,371

answered Jul 05 '12 at 03:33

M.R.

31,425
8
90
281

1

Re your question, i has head Real, not Integer. – rm -rf Jul 05 '12 at 04:08
Yes, Head[1 + .01] is Real; try: i == Round[i] – Mr.Wizard Jul 05 '12 at 06:42
Oh right, thanks! – M.R. Jul 05 '12 at 12:55

How can I make a list animation of images that fade in and out?

2 Answers2