How to convert string to integer list?

Question

Saying we have a string:

"1 2 3 4 5 6"

I want to convert this to integer list. First I do:

In[82]:= str = StringReplace["1 2 3 4 5 6", " " -> ","] // List
Out[82]= {"1,2,3,4,5,6"}

No I need to convert Out[82] to be just {1,2,3,4,5,6}.

Any idea? Thanks!

Answer 1

For performance fiends:

I had an application that had this very need for some huge sets of long integer strings.

kguler's solution is certainly the canonical way, and quite quick, as is Felix's version (I was actually surprised on that one). eldo's solution is probably what most would come up with, but in performance-intensive scenarios the StringSplit is a killer. This is what I use for integer string to digit list conversion:

toDigs=With[{s = Subtract[ToCharacterCode[#], 48]}, Pick[s, UnitStep@s, 1]]&;

(n.b.: If the integer string is sans spaces, just Subtract[ToCharacterCode[#], 48]& suffices, with a nice speed bump.)

On large strings, the performance advantage can be orders of magnitude:

Even on relatively small integer strings it has advantages:

Answer 2

FromDigits /@ StringSplit["1 2 3 4 5 6"]
ToExpression@StringSplit["1 2 3 4 5 6"]
StringCases["1 2 3 4 5 6", ns : NumberString :> FromDigits[ns]]
ToExpression@StringCases["1 2 3 4 5 6", NumberString]

all give

(* {1, 2, 3, 4, 5, 6} *)

Answer 3

Flatten[ImportString["1 2 3 4 5 6", "Table"]]

{1,2,3,4,5,6}

Head /@ %

{Integer, Integer, Integer, Integer, Integer, Integer}

Answer 4

res = ToExpression @ StringSplit["1 2 3 4 5 6", " "]

{1, 2, 3, 4, 5, 6}

 Head /@ res

{Integer, Integer, Integer, Integer, Integer, Integer}

Revision 1

If the substrings are separated by whitespace, one can omit the 2nd argument:

ToExpression @ StringSplit["1 2 3 4 5 6"]

{1, 2, 3, 4, 5, 6}

Answer 5

str = "1 2 3 4 5 6"
Interpreter[DelimitedSequence["Integer"]][str]

{1, 2, 3, 4, 5, 6}

Answer 6

ToExpression["{" <> StringReplace["1 2 3 4 5 6", " " -> ","] <> "}"]

Answer 7

Using ReplaceAll and DeleteCases:

str /. x_ :> DeleteCases[ToExpression@Characters[x], Null]
({1, 2, 3, 4, 5, 6})

Another way, using StringCases and DigitCharacter:

StringCases[str, ns : DigitCharacter :> FromDigits[ns]] // RepeatedTiming
({9.5965810^-6, {1, 2, 3, 4, 5, 6}}*)