How to delete Missing["NotAvailable"] from list of rules?

Question

Considering we have a list of rules:

{ First-> {a-> "aaaa", b-> "bbbb"}, Second-> {c-> "cccc", d-> "dddd", e-> Missing["NotAvailable"], f-> Missing["NotAvailable"] }}

How can I bring this to be:

{ First-> {a-> "aaaa", b-> "bbbb"}, Second-> {c-> "cccc", d-> "dddd" }}

Thanks.

Possible duplicates: (1234), (40169), (55942), (65923). Related: (2655) — Mr.Wizard, Apr 08 '15 at 16:14

score 12 · Accepted Answer · answered Apr 06 '15 at 13:06

list =
 {First -> {a -> "aaaa", b -> "bbbb"}, Second -> {c -> "cccc", d -> "dddd"e -> Missing["NotAvailable"], f -> Missing["NotAvailable"]}}

DeleteCases[list, Rule[_, _Missing], Infinity]

{First -> {a -> "aaaa", b -> "bbbb"}, Second -> {c -> "cccc", d -> "dddd"}}

score 6 · Answer 2 · answered Apr 06 '15 at 20:44

you can use DeleteMissing also

l = {First -> {a -> "aaaa", b -> "bbbb"}, 
  Second -> {c -> "cccc", d -> "dddd", e -> Missing["NotAvailable"], 
    f -> Missing["NotAvailable"]}};

Normal@DeleteMissing[Association@l, Infinity]
(*{First -> {a -> "aaaa", b -> "bbbb"},Second -> {c -> "cccc", d -> "dddd"}}*)

score 4 · Answer 3 · answered Apr 06 '15 at 14:33

4

Here is another alternative using UpValues:

Block[{Missing},
 Missing /: _ -> Missing["NotAvailable"] := Sequence[];
 {First -> {a -> "aaaa", b -> "bbbb"}, 
  Second -> {c -> "cccc", d -> "dddd", e -> Missing["NotAvailable"], 
    f -> Missing["NotAvailable"]}}
 ]
(*
  {First -> {a -> "aaaa", b -> "bbbb"}, Second -> {c -> "cccc", d -> "dddd"}}
*)

answered Apr 06 '15 at 14:33

rcollyer

33,976
7
92
191

That looks familiar – Mr.Wizard Apr 08 '15 at 16:26
@Mr.Wizard really? I never would have guessed. – rcollyer Apr 08 '15 at 17:15
1

@Mr.Wizard Truthfully, I'm enamored with mma's homoiconicity and I think it should be demonstrated at every opportunity. – rcollyer Apr 08 '15 at 17:26
It is nice but beware of packed arrays. – Mr.Wizard Apr 08 '15 at 17:32
@Mr.Wizard packed arrays can be special, along with most things that are AtomQ. – rcollyer Apr 08 '15 at 17:34

penguin77 · Answer 4 · 2015-04-06T14:11:58.677

3

Less elegant than DeleteCases, however an alternative:

exp = {First -> {a -> "aaaa", b -> "bbbb"}, 
  Second -> {c -> "cccc", d -> "dddd", e -> Missing["NotAvailable"], 
    f -> Missing["NotAvailable"]}}

 Delete[exp, Position[exp, _ -> _Missing]]

Or

 Delete[exp, Drop[#, -1] & /@ Position[exp, _Missing]]

(*{First -> {a -> "aaaa", b -> "bbbb"}, Second -> {c -> "cccc", d -> "dddd"}}*)

edited Apr 06 '15 at 14:11

answered Apr 06 '15 at 13:20

penguin77

1,645
9
8

How to delete Missing["NotAvailable"] from list of rules?

4 Answers4