How to switch from array to string?

Question

Considering we have an array:

a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9};

How can I get this to be:

"2/3 4/5 9/7 3/7 1/7 1/9"

Thanks!

Related: (7063), (15032), (20412), (56419) – Mr.Wizard Apr 12 '15 at 16:39 — Mr.Wizard, Apr 12 '15 at 16:39

kglr · Accepted Answer · 2015-04-12T11:19:18.577

I would love this to be uniform for both integer and rational numbers

a2 = {2/3, 4/5, 9/7, 3/7, 1.5, 3, 1/9};


StringTrim@StringJoin[" " <> ToString[#, InputForm] & /@ a2]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)

Row[ToString[#, InputForm] & /@ a2, "  "]
(* 2/3  4/5  9/7  3/7  1.5  3  1/9 *)

StringReplace[ToString[a, InputForm], {"{" | "}" -> "", "," -> " "}]
(* 2/3  4/5  9/7  3/7  1.5  3  1/9 *)

StringJoin[Riffle[ToString[#, InputForm] & /@ a2, " "]]
(* 2/3 4/5 9/7 3/7 1.5 3 1/9 *)

score 4 · Answer 2 · answered Apr 12 '15 at 10:14

4

Or

StringTake[ToString[a, FormatType -> InputForm], {2, -2}]

The inelegant use of StringTake strips off the leading and trailing brackets.

answered Apr 12 '15 at 10:14

High Performance Mark

1,534
1
10
17

Elegant! You can use StringDelete[..., "{" | "}" | ","] instead of StringTake. – István Zachar Apr 12 '15 at 10:29
1

Nice. Btw, this does not give the same form the OP wanted due the "," being there between the numbers. May be just need small modification? – Nasser Apr 12 '15 at 10:51
May be just need small modification? -- Surely, but left as an exercise for the reader :-) – High Performance Mark Apr 12 '15 at 11:46
1

Nice to see you here @HighPerformanceMark ! :-) – Mr.Wizard Apr 12 '15 at 16:47

score 2 · Answer 3 · answered Aug 11 '17 at 07:41

2

Yet another possibility:

a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9, 5, 6, 99/10};
ExportString[{a}, "Table", "FieldSeparators" -> " "]
   "2/3 4/5 9/7 3/7 1/7 1/9 5 6 99/10"

answered Aug 11 '17 at 07:41

J. M.'s missing motivation

124,525
11
401
574

score 2 · Answer 4 · edited Aug 16 '17 at 01:25

2

a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9};
StringJoin@Cases[a, Rational[x_, y_] :> 
   " "<>ToString[x] <> "/" <> ToString[y]]

Mathematica graphics

Reply to comment "I would love this to be uniform for both integer and rational numbers":

a = {2/3, 4/5, 9/7, 3/7, 1/7, 1/9, 5, 6, 99/10};
f[Rational[x_, y_]] := " " <> ToString[x] <> "/" <> ToString[y];
f[x_] := " " <> ToString[x];
StringJoin[f[#] & /@ a]

Mathematica graphics

edited Aug 16 '17 at 01:25

J. M.'s missing motivation

124,525
11
401
574

answered Apr 12 '15 at 09:59

Nasser

143,286
11
154
359

I would love this to be uniform for both integer and rational numbers. Thanks! – SuTron Apr 12 '15 at 10:00

score 2 · Answer 5 · answered Apr 12 '15 at 16:46

2

Terse:

a = {1, 17, 2/3, 4/5, 9/7, 3/7, 1/7, 1/9};

ToString @ Row[InputForm /@ a, " "]

"1 17 2/3 4/5 9/7 3/7 1/7 1/9"

answered Apr 12 '15 at 16:46

Mr.Wizard

271,378
34
587
1,371

How to switch from array to string?

5 Answers5

Linked