How to remove unnecessary brackets in one formula

Question

I have some string,like "3+(3*(2+5))", obvious that some brackets are unnecessary. It can write like "3+3*(2+5)", so I try to use Inactive.

ToExpression["3+(3*(2+5))",StandardForm,Hold]
    //Inactivate[#,Plus|Times] & // ReleaseHold

ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))",StandardForm,Hold]
    //Inactivate[#,Plus|Times] & // ReleaseHold

Sometimes it works,but sometimes it does not work.

Could someone help me? Thanks.

Try converting to InputForm and back to StandardForm. – sacratus Apr 30 '15 at 10:07 — sacratus, Apr 30 '15 at 10:07

score 2 · Answer 1 · answered May 30 '15 at 15:05

The problem is that the head Inactive[Plus] etc. does not inherit the Flat attribute of Plus and Times. One way is to Flatten manually:

expr = ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))", InputForm, 
     Hold] // Inactivate[#, Plus | Times] & // ReleaseHold;
Simplify[expr, TransformationFunctions -> {
    # /. e : Inactive[Plus][__] :> Flatten[e] &,
    # /. e : Inactive[Times][__] :> Flatten[e] &}]

Mathematica graphics

Another way is to get it, by replacing Inactive[Plus] etc. by temporary heads with the Flat attribute.

Module[{p, t},
 SetAttributes[p, Flat];
 SetAttributes[t, Flat];
 ReleaseHold[
   ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))", StandardForm, 
     Hold] /. {Plus -> p, Times -> t}
   ] /. {p -> Inactive[Plus], t -> Inactive[Times]}
 ]

Mathematica graphics

Related Q&A: http://mathematica.stackexchange.com/questions/544/how-do-you-set-attributes-on-subvalues — Michael E2, May 30 '15 at 15:05

k_v · Answer 2 · 2015-04-30T10:52:18.133

(ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))",StandardForm,Hold]//Inactivate[#,Plus|Times]&//ReleaseHold)//.{Inactive[Plus][a___,Inactive[Plus][b_,c_],d___]->Inactive[Plus][a,b,c,d],
Inactive[Times][a___,Inactive[Times][b_,c_],d___]->Inactive[Times][a,b,c,d]}

and one more way, but it suits only for expressions with reals and integers

(ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))", StandardForm, 
    Hold] /. x : _Integer | _Real :> ToString[x]) // ReleaseHold

and this one can take into account non standard symbols like named variables

(ToExpression["((3+4)+(5+6))+((7-8)*(9*(1*2)))", StandardForm, 
    Hold]/. x : _Integer | _Real | _Symbol?Not@NameQ :> ToString[x] // ReleaseHold

The last one has a useless initial '(' – Crypto Oct 28 '16 at 20:16 — Crypto, Oct 28 '16 at 20:16

How to remove unnecessary brackets in one formula

2 Answers2