Automatically load packages at startup

Question

I'm a physics student and I try to simplify my day with Mathematica. Every time I use Mathematica I need Div[], Grad[], Curl[], etc., so I use Needs["VectorAnalysis`"].

My question is: Is there any way to tell Mathematica that the package VectorAnalysis` should always be loaded? It would simplify my day enormously.

By the way, I tried

DeclarePackage["VectorAnalysis`", {"Div", "Grad", "Curl"}]

from the Mathematica tutorial on Automatic Loading of Packages, which says:

When you first use Grad, Mathematica automatically loads the package that defines it.

Unfortunately, nothing happens. The functions are still unknown, until I use Needs["VectorAnalysis`"]

What am I doing wrong, and how do I fix my problem?

Answer 1

As J.M. pointed out, this can be achieved by using an init.m file.

init.m files are loaded on startup. The documentation can be found here.

To load the VectorAnalysis package on each startup, you can write the init file using Export. The snippet below will append a Needs["VectorAnalysis`"] to the kernel init.m file:

initFileName = FileNameJoin[{$UserBaseDirectory, "Kernel", "init.m"}];

(* Make a back-up *)
CopyFile[initFileName, initFileName <> "_" <>
   StringReplace[ToString@Round[DateList[]], " " -> ""] <> ".bak"];

exprs = Import[initFileName, {"Package", "HeldExpressions"}];

Export[initFileName,
    Append[exprs, HoldComplete[Needs["VectorAnalysis`"]]],
    {"Package", "HeldExpressions"}
]

Answer 2

On Mathematica 7 (at least) DeclarePackage doesn't work first time on this Curl example:

DeclarePackage["VectorAnalysis`", {"Div", "Grad", "Curl"}]

v := {3 Xx^2 + 2 Yy + (a  - 3 b)  Zz,
   (b - 7 a) Xx - 5 Yy - Zz,
   2 Xx + c a Yy + 7 Zz}

Curl[v]

{0, 0, 0}

But strangely when v is defined again and run it works:

v := {3 Xx^2 + 2 Yy + (a  - 3 b)  Zz,
   (b - 7 a) Xx - 5 Yy - Zz,
   2 Xx + c a Yy + 7 Zz}

Curl[v]

{1 + a c, -2 + a - 3 b, -2 - 7 a + b}

On the other hand Needs works first time:

Quit

Needs["VectorAnalysis`"]

v := {3 Xx^2 + 2 Yy + (a  - 3 b)  Zz,
   (b - 7 a) Xx - 5 Yy - Zz,
   2 Xx + c a Yy + 7 Zz}

Curl[v]

{1 + a c, -2 + a - 3 b, -2 - 7 a + b}

You could manually add Needs["VectorAnalysis`"] to the init file referred to by Malte, found at FileNameJoin[{$UserBaseDirectory, "Kernel", "init.m"}].