Using Nest on a function that takes a function as one of its arguments

Question

I have a function, nS[f_, xk_], which takes as arguments a function f and a vector xk. It works perfectly when I use it on its own.

nS[t, {1, 0, 0}]

{0.664063, 0.417969, 0.}

But when I try to use Nest, for some reason it won't evaluate the function:

Nest[nS, {t, {1, 0, 0}}, 1]

nS[{t, {1, 0, 0}}]

And if I increase the iterations on Nest I just get nS[nS[nS[...]]].

Answer 1

Edit

Because you do not provide definitions for nS an t, I can not provide a solution based on your code, so I will contrive my own example.

f[fnc_, data_List] := fnc /@ data
sq[x_] := x^2
f[sq, Range @ 3]

{1, 4, 9}

Now to use f with Nest, I simply write

Nest[f[sq, #] &, Range @ 3, 3]

{1, 256, 6561}

The 1-st argument of Nest is a function of one variable, the list that f requires, so the 2-nd argument can be that list alone.

The auxiliary function sq makes the code easier to understand but isn't actually needed. The Nest expression can just as well be written with pure functions.

Nest[f[#^2 &, #] &, Range @ 3, 3]

Answer 2

Since your examples shows your function outputting a simple numeric vector is not not make sense to apply your two-argument function to this result. Presumably you want to keep a constant f_ parameter for every application of nS. The best way to do that is to define a parameterized function:

nS[f_][xk_List] := Developer`PartitionMap[f, xk, 3, 1]

Basic use is almost the same:

nS[Total][Range@5]

{6, 9, 12}

And now you can just write:

NestList[nS[Total], Range[9], 4]

{
{1, 2, 3, 4, 5, 6, 7, 8, 9},
 {6, 9, 12, 15, 18, 21, 24},
  {27, 36, 45, 54, 63},
   {108, 135, 162},
    {405}
}