Computing an integral numerically

Question

P = 0;
l = 0;
x = 4;
κ = 0.01;
n = 5;
q = (κ*n)/2;

Do[Q = (Exp[((-I)*(MathieuCharacteristicA[ν, q] - x^2/4)*(τ/2))])*
       (Integrate[
         (Exp[(-I)*(l - x/2)*(θ)])*(Exp[(I)*(ν)*(θ)])*
         (MathieuC[MathieuCharacteristicA[ν, q], q, θ]),
         {θ, 0, 2 π}
        ])*
       (Integrate[
         (Exp[(I)*(y - x/2)*(z)])*(Exp[(-I)*(ν)*(z)])*
         (MathieuC[MathieuCharacteristicA[ν, q], q, z]),
         {z, 0, 2 π}
        ]);
  P = P + Q, 
  {y, 0, 8, 2}, {ν, 6, 14, 2}
];

Q1 = N[P]

I get error when I get numerical value. But there is no error until value of y is in range 0 to 6. As it increases from 6 to 8, I get the error. When I tried max recurssion limit of 12, I see a "not machine sized integer" error.

Please help.

Answer 1

Sometimes it is just a matter of adjusting the options. Here is a modification of your code that gives an answer fairly quickly and without any messages, using NIntegrate and some of its options:

P = 0;
l = 0;
x = 4;
κ = 0.01`20; (* note increased precision *)
n = 5;
q = (κ*n)/2;

Do[Q = Exp[((-I)*(MathieuCharacteristicA[ν, q] - x^2/4)*τ/2)]*
       NIntegrate[
        Exp[(-I)*(l - x/2)*θ]*Exp[I*ν*θ]*
        MathieuC[MathieuCharacteristicA[ν, q], q, θ],
        {θ, 0, 2 π},
        WorkingPrecision -> 20
       ]*
       NIntegrate[
        Exp[I*(y - x/2)*z]*Exp[(-I)*ν*z]*
        MathieuC[MathieuCharacteristicA[ν, q], q, z],
        {z, 0, 2 π},
        WorkingPrecision -> 20,
        Method -> {"GlobalAdaptive", Method -> "ClenshawCurtisOscillatoryRule"}
       ];
  P = P + Q, 
  {y, 0, 8, 2}, {ν, 6, 14, 2}
];

Q1 = P

I will not copy its result here, since you can easily run it for yourself. Although it gives an output without any complaints, what I cannot tell you is whether that result is anything like correct given other trouble observed with MathieuC under similar circumstances. Hopefully you will be able to tell whether or not the answer it provides is what you expected.