Solving an equation containing an integral numerically

Question

my problem is: I get the result of definite integral and now I need to find the upper limit for the same integral but with opposite sign value so f2=-f1.

   f[x_]:=(E^x m (-1 + x - x0) + E^(b x) n (1 + b (-x + x0)))^2 / 
            ( (a E^(b x) + E^x K1) (E^x m -E^(b x) n)^2 (x - x0) )

The values of the parameters are:

    m = 2.017`100;
    n= 0.87`100;
    K1 = 1;
    a = 21.57`100;
    x0 = -1.53`100;
    b = 0.56827`100;
    x1 = 7.8`10;
    x2 = 10;

I was able to calculate the value of the following definite integral:

firstIntegral = NIntegrate[f[x],{x,x1,x2}]

(*Out: 0.0019499644501301185 *)

I am now trying to find the indefinite integral first and then find the upper limit by this:

    f1[x1_, x2_] := Integrate[f[x], {x, x1, x2}]
    FindRoot[ nv[10, x3] == -firstIntegral, {x3, .001}]

A first version of this question was put on hold due to simple syntax mistakes; I re-edited the question to include and clarify this second part of my problem.

Answer 1

Elvira, I am going to put here what I had put together for an answer to your question. There is still something puzzling about your question though, and that is the fact that you are essentially recalculating the same integral twice, it seems to me.

Here is what I mean:

$$\text{firstIntegral}=\int_{x1}^{x2} \! f(x) \, \mathrm{d}x $$

Then you are looking for $x3$ such that

$$\int_{x2}^{x3} \! f(x) \, \mathrm{d}x = -\int_{x1}^{x2} \! f(x) \, \mathrm{d}x $$

but, considering that if you swap the limits of integration, the integral value changes sign, we can write:

$$\int_{x2}^{x3} \! f(x) \, \mathrm{d}x = -\int_{x1}^{x2} \! f(x) \, \mathrm{d}x = \int_{x2}^{x1} \! f(x) \, \mathrm{d}x $$

... so the $x3$ value you are looking for is $x1$! I wonder if I am misreading your question this second time around...

In any case, I'd like to present some machinery that I think might come in handy for you to solve further questions like this one. In the absence of further clarifications, I will use what we learned above about $x3$to check that the numerical results are correct.

As you said, this is the value of your first integral:

firstIntegral = NIntegrate[f[x], {x, x1, x2}]

(* Out: 0.00194996 *)

Symbolic integration of your function f[x] doesn't get very far, at least on my computer and for reasonable waiting time. So I'll tackle your your problem numerically instead.

To do so , I will define a function that calculates your second integral numerically, but that attempts to do so only when it is fed a numerical value for the integration limits, otherwise the NIntegrate function won't be able to complete its task.

secondIntegral[a_?NumericQ, b_?NumericQ] := NIntegrate[f[x], {x, a, b}]

See this FAQ for further explanation on the topic of NumericQ.

Let's take a look at the value of this integral, using $x2$ as the lower integration limit, as you requested:

Plot[secondIntegral[x2, x3], {x3, 5, x2},
 GridLines -> {None, {-firstIntegral}}, GridLinesStyle -> {Thick, Red}
]

In that plot, I put a $y$-axis grid line indicating the value of -firstIntegral, so that gives us an idea of a) whether a solution exists (it does); b) what a rough estimate for $x3$ might be (somewhere around 8).

I will then use FindRoot to solve the equation numerically, using the rough estimate for $x3$ I got from the plot.

FindRoot[secondIntegral[x2, x3] == -firstIntegral, {x3, 8}]

(* Out: {x3 -> 7.8} *)

Notice that we recover the value of $x1$ you had set at the beginning as expected from the discussion above. Do let me know if I am misunderstanding your problem though.