Given integral, how to plot

Question

I want to use mathematica to visualise some plots, this would help me understand my calculus course. My problem is this:

Given that

x^2 + y^2 <= a^2

Find

\[Integral]\!\(
\*SubscriptBox[\(\[Integral]\), \(D\)]\(\*
TemplateBox[{"x"},
"Abs"] \[DifferentialD]y \[DifferentialD]x\)\)

Now I know how to solve it through polar coordinates, but I am simply interested in how to plot the problem such that I could use it when I get to more difficult integration problems.

Answer 1

Now that the nature of integral has been clarified: $\iint_{D} |x| \mathrm dx\mathrm dy$ where $D$ is region $x^2+y^2<a^2$:

There are a number of ways to evaluate integral:

Integrate[Abs[x], {x, y} \[Element] Disk[{0, 0}, a], 
 Assumptions -> a > 0]
(*Jacobian to conversion to polar coordinates*)
j = Simplify[Det[Outer[D[#1, #2] &, {r Cos[t], r Sin[t]}, {r, t}]]];
Integrate[Abs[r Cos[t]] j, {r, 0, a}, {t, 0, 2 Pi}, 
 Assumptions -> a > 0]
(*using implicitly defined region*)
reg = ImplicitRegion[
   0 < z < Abs[x] && 
    x^2 + y^2 < a^2, {{x, -a, a}, {y, -a, a}, {z, 0, a}}];
Assuming[a > 0, Volume[reg]]

All yield (4 a^3)/3

Visualization:

p1 = Plot3D[Abs[x], {x, -1, 1}, {y, -1, 1}, 
   RegionFunction -> Function[{x, y}, x^2 + y^2 < 1], Mesh -> False];
p2 = ParametricPlot3D[{r Cos[t], r Sin[t], Abs[r Cos[t]]}, {r, 0, 
    1}, {t, 0, 2 Pi}, Mesh -> False];
p3 = RegionPlot3D[reg /. a -> 1, PlotPoints -> 100, Axes -> False, 
   Boxed -> False, Background -> Black];
Column[{p1, p2, p3}]

Answer 2

The region x^2 + y^2 <= a^2 can of course be parametrized as -Sqrt[a^2-x^2] <= y <= Sqrt[a^2-x^2] with -a <= x <= a:

Integrate[Abs[x], {x, -a, a}, {y, -Sqrt[a^2 - x^2], Sqrt[a^2 - x^2]}]
(* ConditionalExpression[(4 a^3)/3, Re[a] > 0 && Im[a] == 0] *)

Or we can do it in polar coordinates (x = r Cos[f], y = r Sin[f], r <= a)

Integrate[r Abs[r Cos[f]], {r, 0, a}, {f, 0, 2 Pi}, Assumptions -> a > 0]
(* (4 a^3)/3 *)

Or we can leave the thinking to Mathematica, making use of the capability of the ImplicitRegion function as well as the capability of Integrate to do integration over regions, rather than integration limits:

reg = ImplicitRegion[x^2 + y^2 <= a^2, {x,y}];

Integrate[Abs[x], Element[{x, y}, reg]]

Plot3D[Abs[x], {x, -3, 3}, {y, -3, 3},
         RegionFunction -> (Element[{#1, #2}, reg /. a -> 3] &),
         Filling -> Axis]

Piecewise[{{(-4*a^3)/3, a < 0}, {0, a == 0}}, (4*a^3)/3]

And the shaded gray volume under the plot is equal to the result of integration (plotted for a = 3).