DFT: why are frequencies mirrored around the frequency axis?

Question

I want to apply Mathematica's DFT procedure, Fourier[], to a Gaussian. Why a Gaussian? Because I know the analytical result.

So I define

a = 0.5;
h[t_] := Exp[-(t^2/a^2)];

The analytic FourierTransform of h using FourierParameters -> {0, -2 Pi} is:

HAnalytic[v] := Sqrt[Pi]*a*Exp[-a^2*Pi^2*v^2];

Then I create time values:

dt = 1/100;
tList = Table[t, {t, 0, 20000 dt, dt}];

and I create sample data:

inputData = h[tList]

I then create the frequency values:

dv = 1/((Length[tList] - 1)*dt);
vList = dv*Table[i, {i, 0, Length[tList] - 1}];

and carry out the DFT calculation:

HDFT = Re[Fourier[inputData]];

Now I plot it:

Show[
 Plot[HAnalytic[v], {v, 0, 1000*dv}, PlotRange -> {{0, 1.5}, {-1, 1}},
   PlotStyle -> Green],
 ListPlot[{Thread[{vList, HDFT}][[1 ;; 500]]}]
 ]

So far no problem. Only the scaling is different.

BUT NOW MY QUESTION!

Why do I get

i.e. the Fourier-transformed values are mirrored around the frequency axis, when using

tListSym = Table[t, {t, -10000 dt, 10000 dt, dt}]

I mean h[tListSym] gives really kind of the whole function to the DFT, as h is symmetric around $t = 0$, whereas h[tList] reproduces only the right hand side of h.

If I look at the values of HDFT, I can see that the values are alternatively positive / negative.

Can someone explain to me what is going on?

Answer 1

The answer is that Fourier does not know your time values and does not see an even function. Thus if we generate your new input data and plot we get

inputData2 = h[tListSym];
ListLinePlot[inputData2, PlotRange -> All]

The problem is thus how to tell Fourier that the first half of your input is for negative x values. We could change the phase of the values created by Fourier or we can put your input into the usual Fourier form of positive values then negative values - a shifted version. Thus

nn = Length[tListSym]
inputData3 = 
Join[inputData2[[(nn - 1)/2 + 1 ;; -1]], 
     inputData2[[1 ;; (nn - 1)/2]]];
ListLinePlot[inputData3, PlotRange -> All]

Thus we are starting with the positive values and then putting the negative values after. Now when we do the Fourier transform we get what you want.

HDFT2 = Fourier[inputData2];
HDFT3 = Fourier[inputData3];

Here I have not taken the real parts as you did. We can compare the two versions

ListPlot[{Re[HDFT2][[1 ;; 500]], Re[HDFT3][[1 ;; 500]]}, 
 PlotRange -> All]

ListPlot[{Im[HDFT2][[1 ;; 500]], Im[HDFT3][[1 ;; 500]]}, 
 PlotRange -> All]

The imaginary part of the shifted version is zero because we have constructed an even function. We now get what you want.

Show[
Plot[HAnalytic[v], {v, 0, 1000*dv}, 
     PlotRange -> {{0, 1.5}, {-1, 1}}, PlotStyle -> Green],
ListPlot[{Thread[{vList, Re[HDFT2]}][[1 ;; 500]]}, PlotStyle -> Blue],
ListPlot[{Thread[{vList, HDFT3}][[1 ;; 500]]}, PlotStyle -> Brown]
 ]

On a secondary point I think you are off by one point in defining your frequency values. The increment should be 1/(Length[] dt).

I suppose a deeper question is why does Fourier do positive values then negative values? There is an assumption of a periodic function so it does not matter. However, it is often a nuisance as you have found.

With regard to getting the scaling correct you need to work out your version of Parseval's Theorem using FourierParameters.