How to get multiplication of the elements of a specific list/Matrix

Question

Assume there is a list:

List1={a,b,c,d};

Then I want to get these calculation:

Output1= a
Output2= a*b
Output3= a*b*c
Output4= a*b*c*d

Could you please help me with this problem? Thank you in advance.

FoldList[Times, 1, List1] // Rest – Bob Hanlon Jul 01 '15 at 12:56 — Bob Hanlon, Jul 01 '15 at 12:56

score 5 · Accepted Answer · answered Jul 01 '15 at 12:56

5

list1 = {a, b, c, d};

Rest[FoldList[Times, 1, list1]]

Scan[Print, %]

a
a b
a b c
a b c d

answered Jul 01 '15 at 12:56

Karsten7

score 3 · Answer 2 · answered Jul 01 '15 at 16:28

3

You can also use Accumulate

list1 = {a, b, c, d};

Times @@@ Accumulate[list1]
(* or Accumulate[list1] /. Plus -> Times *)

{a, a b, a b c, a b c d}

... or ReplaceList:

ReplaceList[list1, {x__, ___} :> Times[x]]

{a, a b, a b c, a b c d}

answered Jul 01 '15 at 16:28

kglr

2

I am not sure it can be assumed that unwanted evaluation will not take place here. – Mr.Wizard Jul 01 '15 at 16:40

score 3 · Answer 3 · edited Apr 13 '17 at 12:55

3

My version of Bob Hanlon's comment solution:

list1 = {a, b, c, d};

FoldList[Times, list1]

% // Column

{a, a b, a b c, a b c d}
a
a b
a b c
a b c d

edited Apr 13 '17 at 12:55

Community

answered Jul 01 '15 at 16:39

Mr.Wizard

3 Answers3