Multiple lines in an If statement

Question

What I am wondering is how do you perform multiple lines when using the If statement. I know the following is not proper Mathematica code, but how would I do this in Mathematica?

if(x<1,
 y=2x;
 z=2y
else
 y=x/2;
 z=y/2
)

Mr. Wizard help:

It does work. For example:

In[181]:= x = 0; If[x < 1, y = 2 x; z = 2 y, y = x/2; z = y/2]

Out[181]= 0

Another example:

In[182]:= x = 2; If[x < 1, y = 2 x; z = 2 y, y = x/2; z = y/2]

Out[182]= 1/2

But if the expressions are quite long and complicated, maybe this approach?

In[180]:= x = 2; If[x < 1,
 {
  y = 2 x;
  z = 2 y
  },
 {
  y = x/2;
  z = y/2
  }
 ]


Out[180]= {1/2}

Yes, note the difference here between commas and semicolons. — J. M.'s missing motivation, Jul 01 '15 at 16:52
@Mr.Wizard. It does work. See my edits to the my original post. What I am really thinking about is if such and such is true, then I am going to write a number of steps. My approach above does do some nice indentation and makes things easier to read and understand, but is it the best approach? — David, Jul 01 '15 at 17:03
You should look up CompoundExpression in the docs, and the tutorial linked from that page. — Jens, Jul 01 '15 at 17:25

score 15 · Accepted Answer · answered Jul 01 '15 at 17:38

It seems this question is now purely about style and will probably be closed. However I think you may be looking for this:

If[x < 1,
 (
  y = 2 x;
  z = 2 y
 ),
 (
  y = x/2;
  z = y/2
 )
]

Though I would prefer (hat tip to WReach's comma placement):

If[x < 1,

  y = 2 x;
  z = 2 y

, y = x/2;
  z = y/2

]

If your code is very long I suggest you modularize it, i.e.:

doIfTrue[] := (
  y = 2 x;
  z = 2 y
)

doIfFalse[] := (
  y = x/2;
  z = y/2
)

If[x < 1, doIfTrue[], doIfFalse[]]

Or a more functional equivalent:

doIf[] /; x < 1 := (
  y = 2 x;
  z = 2 y
)

doIf[] /; ! x < 1 := (
  y = x/2;
  z = y/2
)

doIf[]

@MrWizard. Many helpful examples here. Thanks for your help. — David, Jul 02 '15 at 17:49

Multiple lines in an If statement

1 Answers1

Related